media-sound/ncmpcpp/ncmpcpp-0.2.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.2.4.ebuild,v 1.1 2008/10/15 16:50:50 yngwin Exp $

inherit eutils

DESCRIPTION="An ncurses mpd client, ncmpc clone with some new features, written in C++"
HOMEPAGE="http://unkart.ovh.org/ncmpcpp"
SRC_URI="http://unkart.ovh.org/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
IUSE="curl taglib unicode"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="sys-libs/ncurses
	curl? ( net-misc/curl )
	taglib? ( media-libs/taglib )"
RDEPEND="${DEPEND}"

pkg_setup() {
	if ! built_with_use sys-libs/ncurses unicode && use unicode ; then
		eerror "Please recompile sys-libs/ncurses with the unicode useflag"
		die
	fi
}

src_compile() {
	econf $(use_enable unicode) $(use_with curl) $(use_with taglib) \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	make install DESTDIR="${D}" docdir="${ROOT}/usr/share/doc/${PF}" \
		|| die "install failed"
	prepalldocs
}

pkg_postinst() {
	echo
	elog "Example configuration files have been installed at"
	elog "${ROOT}usr/share/doc/${PF}"
	elog "${P} now uses ~/.ncmpcpp/config and ~/.ncmpcpp/keys"
	elog "as configuration files. If you have used a previous version,"
	elog "please move your configuration files to the new location."
	echo
}