sci-libs/grib_api/grib_api-1.9.5-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/grib_api/grib_api-1.9.5-r1.ebuild,v 1.4 2011/06/21 15:18:12 jlec Exp $

EAPI=2
inherit eutils fortran-2 autotools

DESCRIPTION="Library for decoding WMO FM-92 GRIB messages"
HOMEPAGE="http://www.ecmwf.int/products/data/software/grib_api.html"
SRC_URI="http://www.ecmwf.int/products/data/software/download/software_files/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples fortran jpeg2k openmp png perl python static-libs"

DEPEND="
	fortran? ( virtual/fortran )
	jpeg2k? ( || ( media-libs/jasper media-libs/openjpeg ) )
	png? ( media-libs/libpng )
	python? ( dev-python/numpy )"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-autotools.patch \
		"${FILESDIR}"/${P}-32bit.patch
	eautoreconf
}

src_configure() {
	econf \
		--enable-install-system-perl \
		$(use_enable fortran) \
		$(use_enable jpeg2k jpeg) \
		$(use_enable openmp omp-packing) \
		$(use_enable python) \
		$(use_enable python numpy) \
		$(use_enable static-libs static) \
		$(use_with perl) \
		$(use_with png png-support)

}

src_install() {
	emake DESTDIR="${D}" install  || die "emake install failed"
	dodoc AUTHORS ChangeLog README
	if use doc; then
		dohtml html/* || die
	fi
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		emake clean
		doins -r * || die
	fi
}