sci-libs/libpdb++/libpdb++-040728.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libpdb++/libpdb++-040728.ebuild,v 1.3 2010/03/07 21:59:04 jlec Exp $

EAPI="3"

inherit eutils toolchain-funcs

DESCRIPTION="PDB Record I/O Libraries -- c++ version"
HOMEPAGE="http://www.cgl.ucsf.edu/Overview/software.html"
SRC_URI="mirror://gentoo/${P}.shar"

SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
LICENSE="BSD"
IUSE=""

RDEPEND=""
DEPEND="${RDEPEND}
	app-arch/sharutils"

S="${WORKDIR}"/${PN}

src_unpack() {
	"${EPREFIX}"/usr/bin/unshar "${DISTDIR}"/${A} || die
}

src_prepare() {
	epatch "${FILESDIR}"/${PV}-dynlib.patch
}

src_compile() {
	emake \
		CXX="$(tc-getCXX)" \
		CCFLAGS="${CXXFLAGS} -fPIC -felide-constructors" \
		|| die
}

src_install() {
	dolib.a ${PN}.a || die
	dolib.so ${PN}.so.0.1 || die
	dosym ${PN}.so.0.1 /usr/$(get_libdir)/${PN}.so.0
	dosym ${PN}.so.0.1 /usr/$(get_libdir)/${PN}.so
	insinto /usr/include/${PN}
	doins *.h || die
}