sys-process/cronie/cronie-1.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/cronie/cronie-1.2.ebuild,v 1.1 2009/02/17 22:09:35 bangert Exp $

inherit cron eutils

DESCRIPTION="Cronie is a standard UNIX daemon cron based on the original vixie-cron."
SRC_URI="https://fedorahosted.org/releases/c/r/cronie/${P}.tar.gz"
HOMEPAGE="https://fedorahosted.org/cronie/wiki"

LICENSE="as-is BSD BSD-2"
KEYWORDS="~x86"
IUSE="inotify pam"

DEPEND="pam? ( virtual/pam )"

#cronie supports /etc/crontab
CRON_SYSTEM_CRONTAB="yes"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-pathnames.h-fix-SPOOL_DIR.patch"
}

src_compile() {
	econf \
		$(use_with inotify ) \
		$(use_with pam ) \
		--with-daemon_username=cron \
		--with-daemon_groupname=cron \
		--with-crontabdir=/var/spool/cron/crontabs \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make install DESTDIR="${D}" || die "install failed"

	docrondir
	fowners root:cron /usr/bin/crontab
	fperms 2750 /usr/bin/crontab

	insinto /etc
	newins "${FILESDIR}/${P}-crontab" crontab
	newins "${FILESDIR}/${P}-cron.deny" cron.deny

	keepdir /etc/cron.d
	newinitd "${FILESDIR}/${P}-initd" cronie
	dodoc NEWS AUTHORS README
}

pkg_postinst() {
	cron_pkg_postinst
}