Add elibtoolize to gstreamer as it is required for cross-compilation.

Keyword the newest version to have some time for submitting the
changes to bugzilla.

2 files changed, 61 insertions, 0 deletions

diff --git a/media-libs/gstreamer/Manifest b/media-libs/gstreamer/Manifest
index 88f75c9..ddc19f5 100644
--- a/media-libs/gstreamer/Manifest
+++ b/media-libs/gstreamer/Manifest
@@ -1,2 +1,4 @@
 DIST gstreamer-0.10.23.tar.bz2 2871267 RMD160 7491281501adca311fd0d2cb8c92cd278e095fd2 SHA1 861af545b51be56b5782a636844f2e888ea7c90c SHA256 cf750821040102d2c9fbfed56472a86fd0d8c24ada37901c41867c88438a776d
+DIST gstreamer-0.10.25.tar.bz2 3045572 RMD160 79f0d117f46d4138acb35fac6594a7aeba4c4a7e SHA1 e3cda2dcac9dbbfc2e61ba79fcd3bff1313dc7f4 SHA256 39b2ba7b3bfa8df6d998a9461e7091c27757e36a53e93969d7d9982a56526578
 EBUILD gstreamer-0.10.23.ebuild 1614 RMD160 0827e7db97714b7b8943fb0f4fcc29a97047e287 SHA1 1023c1eda8cd8a61a4e2b5209c1aefd59dd9bada SHA256 dc277f6be451c4d9264f03e214c34cd22b063f49bd0d32ed02d6bd11119954e6
+EBUILD gstreamer-0.10.25.ebuild 1659 RMD160 209c023c91eebf308a3397619b3669f277be173e SHA1 79c28eed7d1ff8d39c120482ba82beb60a8ae410 SHA256 25faac5c21a5a9e4373924168cbf1bafb95c9d41dbb1c9812932162b603e6d87
diff --git a/media-libs/gstreamer/gstreamer-0.10.25.ebuild b/media-libs/gstreamer/gstreamer-0.10.25.ebuild
new file mode 100644
index 0000000..3ce277d
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.10.25.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.25.ebuild,v 1.1 2009/11/15 23:47:42 leio Exp $
+
+EAPI=2
+
+inherit eutils libtool multilib versionator
+
+# Create a major/minor combo for our SLOT and executables suffix
+PV_MAJ_MIN=$(get_version_component_range '1-2')
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="nls test"
+
+RDEPEND=">=dev-libs/glib-2.16:2
+	dev-libs/libxml2
+	>=dev-libs/check-0.9.2"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	# Needed for cross-compilation
+	elibtoolize
+}
+
+src_configure() {
+	# Disable static archives, dependency tracking and examples
+	# to speed up build time
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		$(use_enable nls) \
+		--disable-valgrind \
+		--disable-examples \
+		--enable-check \
+		--disable-introspection \
+		$(use_enable test tests) \
+		--with-package-name="GStreamer ebuild for Gentoo" \
+		--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE
+
+	# Remove unversioned binaries to allow SLOT installations in future
+	cd "${D}"/usr/bin
+	local gst_bins
+	for gst_bins in $(ls *-${PV_MAJ_MIN}); do
+		rm -f ${gst_bins/-${PV_MAJ_MIN}/}
+	done
+}