1 files changed, 83 insertions, 0 deletions
diff --git a/app-arch/engrampa/engrampa-1.10.1.ebuild b/app-arch/engrampa/engrampa-1.10.1.ebuild
new file mode 100644
index 0000000..6914918
--- /dev/null
+++ b/app-arch/engrampa/engrampa-1.10.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 versionator
+
+MATE_BRANCH="$(get_version_component_range 1-2)"
+
+SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
+DESCRIPTION="Engrampa archive manager for MATE"
+HOMEPAGE="http://mate-desktop.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="caja magic"
+
+RDEPEND=">=x11-libs/gtk+-2.24.0:2
+	>=dev-libs/glib-2.32.0:2
+	>=dev-libs/json-glib-0.14:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango:0
+	virtual/libintl:0
+	caja? ( >=mate-base/caja-1.10:0 )
+	magic? ( sys-apps/file )
+	!!app-arch/mate-file-archiver"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35:*
+	dev-util/itstool:0
+	>=mate-base/mate-common-1.8:0
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Drop DEPRECATED flags as configure option doesn't do it, bug #385453
+	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
+		copy-n-paste/Makefile.am copy-n-paste/Makefile.in || die
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-run-in-place \
+		--disable-packagekit \
+		--disable-deprecations \
+		--with-gtk=2.0 \
+		$(use_enable caja caja-actions) \
+		$(use_enable magic)
+}
+
+DOCS="AUTHORS HACKING MAINTAINERS NEWS README TODO"
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog ""
+	elog "${PN} is a frontend for several archiving utilities. If you want a"
+	elog "particular achive format supported install the relevant package."
+	elog
+	elog "For example:"
+	elog "  7-zip   : emerge app-arch/p7zip"
+	elog "  ace     : emerge app-arch/unace"
+	elog "  arj     : emerge app-arch/arj"
+	elog "  cpio    : emerge app-arch/cpio"
+	elog "  deb     : emerge app-arch/dpkg"
+	elog "  iso     : emerge app-cdr/cdrtools"
+	elog "  jar,zip : emerge app-arch/zip  or  emerge app-arch/unzip"
+	elog "  lha     : emerge app-arch/lha"
+	elog "  lzma    : emerge app-arch/xz-utils"
+	elog "  lzop    : emerge app-arch/lzop"
+	elog "  rar     : emerge app-arch/unrar"
+	elog "  rpm     : emerge app-arch/rpm"
+	elog "  unstuff : emerge app-arch/stuffit"
+	elog "  zoo     : emerge app-arch/zoo"
+}