1 files changed, 77 insertions, 0 deletions
diff --git a/app-arch/engrampa/engrampa-1.12.0-r1.ebuild b/app-arch/engrampa/engrampa-1.12.0-r1.ebuild
new file mode 100644
index 0000000..48c44f3
--- /dev/null
+++ b/app-arch/engrampa/engrampa-1.12.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="Engrampa archive manager for MATE"
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="caja gtk3 magic packagekit"
+
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	>=dev-libs/json-glib-0.14:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango:0
+	virtual/libintl:0
+	caja? ( >=mate-base/caja-1.8[gtk3(-)=] )
+	!gtk3? ( >=x11-libs/gtk+-2.24.0:2 )
+	gtk3? ( >=x11-libs/gtk+-3.0:3 )
+	magic? ( sys-apps/file )
+	packagekit? ( app-admin/packagekit-base )
+	!!app-arch/mate-file-archiver"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.50.1:*
+	dev-util/itstool:0
+	sys-devel/gettext:*
+	virtual/pkgconfig:*"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.10.2-p7zip-15.09-compat.patch"
+	"${FILESDIR}/${PN}-1.10.2-p7zip-15.14-compat.patch"
+)
+
+src_configure() {
+	mate_src_configure \
+		--disable-run-in-place \
+		--disable-deprecations \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_enable caja caja-actions) \
+		$(use_enable magic) \
+		$(use_enable packagekit)
+}
+
+pkg_postinst() {
+	mate_pkg_postinst
+
+	elog ""
+	elog "${PN} is a frontend for several archiving utilities. If you want a"
+	elog "particular achive format supported install the relevant package."
+	elog
+	elog "For example:"
+	elog "  7-zip   : emerge app-arch/p7zip"
+	elog "  ace     : emerge app-arch/unace"
+	elog "  arj     : emerge app-arch/arj"
+	elog "  cpio    : emerge app-arch/cpio"
+	elog "  deb     : emerge app-arch/dpkg"
+	elog "  iso     : emerge app-cdr/cdrtools"
+	elog "  jar,zip : emerge app-arch/zip  or  emerge app-arch/unzip"
+	elog "  lha     : emerge app-arch/lha"
+	elog "  lzma    : emerge app-arch/xz-utils"
+	elog "  lzop    : emerge app-arch/lzop"
+	elog "  rar     : emerge app-arch/unrar"
+	elog "  rpm     : emerge app-arch/rpm"
+	elog "  unstuff : emerge app-arch/stuffit"
+	elog "  zoo     : emerge app-arch/zoo"
+}