kde-apps/cantor: 22.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
new file mode 100644
index 0000000000..6421718303
--- /dev/null
+++ b/kde-apps/cantor/Manifest
@@ -0,0 +1 @@
+DIST cantor-22.12.2.tar.xz 9251040 BLAKE2B f57e2a06d1db65e72d56bcaa3159e8cc762047d5415a58e2492c1ca3622fc14959788d249bcb76fa01375541f6c1e6c8c6f8f2c34d28743f837872ede41b86e4 SHA512 6d6ce5fa9d7969a8afe99501a9047521cff29333f3041d8fb80c8a278ea6ce68a443a7cff203366992176998b18d7e16d3bb7fbbb5940a1ea33f4604b79e8859
diff --git a/kde-apps/cantor/cantor-22.12.2.ebuild b/kde-apps/cantor/cantor-22.12.2.ebuild
new file mode 100644
index 0000000000..b1a1ba2ad2
--- /dev/null
+++ b/kde-apps/cantor/cantor-22.12.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{9..11} )
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org lua-single optfeature python-single-r1
+
+DESCRIPTION="Interface for doing mathematics and scientific computing"
+HOMEPAGE="https://apps.kde.org/cantor/ https://edu.kde.org/cantor/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+analitza julia lua postscript python qalculate R"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test"
+
+# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
+DEPEND="
+	app-text/poppler[qt5]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qthelp-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
+	julia? ( dev-lang/julia )
+	lua? ( ${LUA_DEPS} )
+	qalculate? (
+		sci-libs/cln
+		sci-libs/libqalculate:=
+	)
+	postscript? ( app-text/libspectre )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-qt/qtdbus-${QTMIN}:5
+	)
+	R? ( dev-lang/R )
+"
+RDEPEND="${DEPEND}
+	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
+		|| (
+			sci-mathematics/maxima
+			sci-mathematics/octave
+		)
+	) ) ) ) ) )
+"
+BDEPEND="x11-misc/shared-mime-info"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	use julia && addpredict /proc/self/mem # bug 602894
+
+	local mycmakeargs=(
+		$(cmake_use_find_package analitza Analitza5)
+		$(cmake_use_find_package julia Julia)
+		$(cmake_use_find_package lua LuaJIT)
+		-DUSE_LIBSPECTRE=$(usex postscript)
+		$(cmake_use_find_package python Python3)
+		$(cmake_use_find_package qalculate Qalculate)
+		$(cmake_use_find_package R R)
+	)
+	use lua && mycmakeargs+=(
+		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
+		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
+	)
+	use python && mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Maxima backend" sci-mathematics/maxima
+		optfeature "Octave backend" sci-mathematics/octave
+		optfeature "LaTeX support" virtual/latex-base
+	fi
+	ecm_pkg_postinst
+}