net-p2p/ktorrent: 22.03.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 96 insertions, 0 deletions

diff --git a/net-p2p/ktorrent/Manifest b/net-p2p/ktorrent/Manifest
index d6db7ef3ab..f218fcd4c5 100644
--- a/net-p2p/ktorrent/Manifest
+++ b/net-p2p/ktorrent/Manifest
@@ -1 +1,2 @@
 DIST ktorrent-22.03.80.tar.xz 2055480 BLAKE2B 41a8cf69c4ab7272d00c662f6ba4c89dc005aa67a6d892f9b4ba8d07479e233b64f19287653d3225d0dc2152f1414ed8ebf0c0b77f1c116f9ab4c09dbdeab3ef SHA512 1d66cbb42ad371ea040dff999ea412391e04bb7d4b49fcc0651c2b8cc5a8bb2ee0aa6f22d9a13a094be4c2133c1ea9ece543c3165c08176ac57ee574e62b3b10
+DIST ktorrent-22.03.90.tar.xz 2055916 BLAKE2B fd2f318ca0e6201b03866b10f1a986aa733fa4de8229f09b34da8943947232474bf265a7422a411e369b07210358b7dec18411edacacd94aeda1e9006419babe SHA512 35c5c3c8942f1e7ef2cda6b527bc3df46e3844965582dfc379ea8436d930ad0b3ebed3b90d4ba12e9413c4ed3f9c312b9683496a74d0093da7874b627b415fe7
diff --git a/net-p2p/ktorrent/ktorrent-22.03.90.ebuild b/net-p2p/ktorrent/ktorrent-22.03.90.ebuild
new file mode 100644
index 0000000000..33022e7b28
--- /dev/null
+++ b/net-p2p/ktorrent/ktorrent-22.03.90.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="optional"
+KDE_GEAR="true"
+KFMIN=5.92.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=net-libs/libktorrent-${PVCUT}:5
+	infowidget? ( dev-libs/geoip )
+	mediaplayer? (
+		>=media-libs/phonon-4.11.0
+		>=media-libs/taglib-1.5
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:5
+		>=kde-frameworks/syndication-${KFMIN}:5
+	)
+	shutdown? ( kde-plasma/libkworkspace:5 )
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:5 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:5 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:5
+		>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF5Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}