blob: 2a9bf3c9f8709680363069cf11e19b51ee220239 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="forceoptional"
ECM_TEST="forceoptional"
PVCUT=$(ver_cut 1-3)
KFMIN=5.75.0
QTMIN=5.15.1
VIRTUALX_REQUIRED="test"
inherit ecm kde.org optfeature
DESCRIPTION="Email client, supporting POP3 and IMAP mailboxes."
HOMEPAGE="https://kde.org/applications/en/kmail2
https://kontact.kde.org/components/kmail.html"
LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
SLOT="5"
KEYWORDS=""
IUSE="telemetry"
BDEPEND="
dev-libs/libxslt
test? ( >=kde-apps/akonadi-${PVCUT}:5[tools] )
"
COMMON_DEPEND="
>=app-crypt/gpgme-1.11.1[cxx,qt5]
>=dev-qt/qtcore-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-apps/akonadi-${PVCUT}:5
>=kde-apps/akonadi-contacts-${PVCUT}:5
>=kde-apps/akonadi-mime-${PVCUT}:5
>=kde-apps/akonadi-search-${PVCUT}:5
>=kde-apps/kidentitymanagement-${PVCUT}:5
>=kde-apps/kmailtransport-${PVCUT}:5
>=kde-apps/kmime-${PVCUT}:5
>=kde-apps/kontactinterface-${PVCUT}:5
>=kde-apps/kpimtextedit-${PVCUT}:5
>=kde-apps/libgravatar-${PVCUT}:5
>=kde-apps/libkdepim-${PVCUT}:5
>=kde-apps/libkleo-${PVCUT}:5
>=kde-apps/libksieve-${PVCUT}:5
>=kde-apps/libktnef-${PVCUT}:5
>=kde-apps/mailcommon-${PVCUT}:5
>=kde-apps/messagelib-${PVCUT}:5
>=kde-apps/pimcommon-${PVCUT}:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
>=kde-frameworks/kcalendarcore-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcontacts-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kitemviews-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/sonnet-${KFMIN}:5
telemetry? ( dev-libs/kuserfeedback:5 )
"
DEPEND="${COMMON_DEPEND}
>=kde-apps/kcalutils-${PVCUT}:5
>=kde-apps/kldap-${PVCUT}:5
test? ( >=kde-apps/akonadi-${PVCUT}:5[sqlite] )
"
RDEPEND="${COMMON_DEPEND}
>=kde-apps/kdepim-runtime-${PVCUT}:5
>=kde-apps/kmail-account-wizard-${PVCUT}:5
"
RESTRICT+=" test" # bug 616878
src_prepare() {
ecm_src_prepare
use handbook || cmake_run_in ktnef cmake_comment_add_subdirectory doc
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package telemetry KUserFeedback)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "Optional dependencies:"
optfeature "Virus detection" app-antivirus/clamav
optfeature "Spam filtering" mail-filter/bogofilter mail-filter/spamassassin
optfeature "Fancy e-mail headers and useful plugins" kde-apps/kdepim-addons:${SLOT}
optfeature "Crypto config and certificate details GUI" kde-apps/kleopatra:${SLOT}
fi
ecm_pkg_postinst
}
|
GitWeb