blob: 6b1f05507126041b866341dae896db0fda113aa2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
QTMIN=5.14.1
inherit cmake kde.org python-any-r1
DESCRIPTION="Extra modules and scripts for CMake"
HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
LICENSE="BSD"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
IUSE="doc test"
BDEPEND="
doc? (
${PYTHON_DEPS}
$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
>=dev-qt/qthelp-${QTMIN}:5
)
test? (
>=dev-qt/linguist-tools-${QTMIN}:5
>=dev-qt/qtcore-${QTMIN}:5
)
"
RDEPEND="
app-arch/libarchive[bzip2]
"
RESTRICT+=" !test? ( test )"
PATCHES=(
"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
"${FILESDIR}/${PN}-5.65.0-disable-qmlplugindump.patch"
)
python_check_deps() {
has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
}
pkg_setup() {
use doc && python-any-r1_pkg_setup
}
src_prepare() {
cmake_src_prepare
# Requires PyQt5, bug #680256
sed -i -e "/^if(NOT SIP_Qt5Core_Mod_FILE)/s/NOT SIP_Qt5Core_Mod_FILE/TRUE/" \
tests/CMakeLists.txt || die "failed to disable GenerateSipBindings tests"
}
src_configure() {
local mycmakeargs=(
-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
-DBUILD_QTHELP_DOCS=$(usex doc)
-DBUILD_HTML_DOCS=$(usex doc)
-DBUILD_MAN_DOCS=$(usex doc)
-DBUILD_TESTING=$(usex test)
)
cmake_src_configure
}
src_test() {
# ECMToolchainAndroidTest passes but then breaks src_install
# ECMPoQmToolsTest is broken, bug #627806
# possible race condition with multiple jobs, bug #701854
local myctestargs=(
-j1
-E "(ECMToolchainAndroidTest|ECMPoQmToolsTest)"
)
cmake_src_test
}
|
GitWeb
