blob: 15e8cc91cabd7b428e2b460bd8c2793694707a7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
KDE_HANDBOOK="forceoptional"
KDE_TEST="true"
KMNAME="${PN}-kde"
KDE_SELINUX_MODULE="${PN}"
inherit kde5
if [[ ${KDE_BUILD_TYPE} = release ]]; then
SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${KMNAME}-${PV}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Adds communication between KDE Plasma and your smartphone"
HOMEPAGE="https://www.kde.org/ https://community.kde.org/KDEConnect"
LICENSE="GPL-2+"
IUSE="app bluetooth mousepad sms wayland"
DEPEND="
$(add_frameworks_dep kcmutils)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kdbusaddons)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep knotifications)
$(add_frameworks_dep kservice)
$(add_frameworks_dep kwidgetsaddons)
$(add_qt_dep qtdbus)
$(add_qt_dep qtdeclarative)
$(add_qt_dep qtgui)
$(add_qt_dep qtnetwork)
$(add_qt_dep qtwidgets)
$(add_qt_dep qtx11extras)
>=app-crypt/qca-2.1.0:2[qt5(+),ssl]
app? ( $(add_frameworks_dep kdeclarative) )
bluetooth? ( $(add_qt_dep qtbluetooth) )
mousepad? (
x11-libs/libfakekey
x11-libs/libX11
x11-libs/libXtst
)
sms? ( $(add_frameworks_dep kpeople) )
wayland? ( $(add_frameworks_dep kwayland) )
"
RDEPEND="${DEPEND}
net-fs/sshfs
app? ( $(add_frameworks_dep kirigami) )
sms? ( $(add_frameworks_dep kirigami) )
!kde-misc/kdeconnect:4
"
RESTRICT+=" test"
src_prepare() {
kde5_src_prepare
sed \
-e 's#${LIBEXEC_INSTALL_DIR}#@KDE_INSTALL_FULL_LIBEXECDIR@#' \
-i daemon/kdeconnectd.desktop.cmake || die
}
src_configure() {
local mycmakeargs=(
-DEXPERIMENTALAPP_ENABLED=$(usex app)
-DBLUETOOTH_ENABLED=$(usex bluetooth)
$(cmake-utils_use_find_package mousepad LibFakeKey)
-DSMSAPP_ENABLED=$(usex sms)
$(cmake-utils_use_find_package wayland KF5Wayland)
)
kde5_src_configure
}
pkg_postinst(){
kde5_pkg_postinst
elog "The Android .apk file is available via"
elog "https://play.google.com/store/apps/details?id=org.kde.kdeconnect_tp"
elog "or via"
elog "https://f-droid.org/repository/browse/?fdid=org.kde.kdeconnect_tp"
}
|
GitWeb