blob: 0fdde3aac2daa23bb2a23cbafe4fa8536801cbd1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_TEST="true"
KDE_ORG_NAME="plasma-workspace"
KFMIN=5.106.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.9
inherit ecm plasma.kde.org
DESCRIPTION="Workspace library to interact with the Plasma session manager"
S="${S}/${PN}"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS=""
IUSE=""
RDEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtx11extras-${QTMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-plasma/kscreenlocker-${PVCUT}:5
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXau
"
DEPEND="${RDEPEND}
>=kde-plasma/kwin-${PVCUT}:5
"
src_prepare() {
# delete colliding libkworkspace translations, let ecm_src_prepare do its magic
find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
rm -rf po/*/docs || die
cp -a ../po ./ || die
eapply "${FILESDIR}/${PN}-5.27.9-standalone.patch"
sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" -i CMakeLists.txt || die
cat >> CMakeLists.txt <<- _EOF_ || die
ki18n_install(po)
_EOF_
ecm_src_prepare
}
|
GitWeb
