app-emacs/company-coq: new package; add 1.0.1_p20210708

2021.07.08 snapshot

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

5 files changed, 75 insertions, 0 deletions

diff --git a/app-emacs/company-coq/Manifest b/app-emacs/company-coq/Manifest
new file mode 100644
index 000000000000..c02201ab2771
--- /dev/null
+++ b/app-emacs/company-coq/Manifest
@@ -0,0 +1 @@
+DIST company-coq-1.0.1_p20210708.tar.gz 3803957 BLAKE2B d2bb3022228cc7a103d4343e914ec20cf539405062e475c7be6cd0db776490a7af35f10fc9e712733bd8f7c6667a05f8d3d6c4321820a61da0847b8bc718c182 SHA512 92a7d0bf8326460519e5f47fe1e9779a4cc2d2bf069898e1797fabf483535eca8244c1ea36bc525aac418e2c26036a8580076435ccbfaa5bdc2e6ee6f133b655
diff --git a/app-emacs/company-coq/company-coq-1.0.1_p20210708.ebuild b/app-emacs/company-coq/company-coq-1.0.1_p20210708.ebuild
new file mode 100644
index 000000000000..968938b2b0f6
--- /dev/null
+++ b/app-emacs/company-coq/company-coq-1.0.1_p20210708.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+H=382db93374380e5db56f02934ee32bbe39159019
+
+inherit elisp
+
+DESCRIPTION="Collection of extensions for Proof General's Coq mode"
+HOMEPAGE="https://github.com/cpitclaudel/company-coq/"
+SRC_URI="https://github.com/cpitclaudel/${PN}/archive/${H}.tar.gz
+		-> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${H}
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	app-emacs/company-math
+	app-emacs/company-mode
+	app-emacs/dash
+	app-emacs/yasnippet
+"
+BDEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-refman-path.patch )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare(){
+	default
+
+	sed -i "s|@SITEETC@|${EPREFIX}${SITEETC}|" ./company-coq.el || die
+}
+
+src_install() {
+	elisp_src_install
+	einstalldocs
+
+	insinto "${SITEETC}"
+	doins -r ./refman
+}
diff --git a/app-emacs/company-coq/files/50company-coq-gentoo.el b/app-emacs/company-coq/files/50company-coq-gentoo.el
new file mode 100644
index 000000000000..431f7e90ae73
--- /dev/null
+++ b/app-emacs/company-coq/files/50company-coq-gentoo.el
@@ -0,0 +1 @@
+(add-to-list 'load-path "@SITELISP@")
diff --git a/app-emacs/company-coq/files/company-coq-refman-path.patch b/app-emacs/company-coq/files/company-coq-refman-path.patch
new file mode 100644
index 000000000000..96c642f1aea0
--- /dev/null
+++ b/app-emacs/company-coq/files/company-coq-refman-path.patch
@@ -0,0 +1,13 @@
+index 3a984878..9a42fed9 100644
+--- a/company-coq.el
++++ b/company-coq.el
+@@ -762,8 +762,7 @@ Useful as a value for `company-coq-completion-predicate'."
+   "Full path of this script.")
+ 
+ (defconst company-coq-refman-path
+-  (when company-coq-script-full-path
+-    (expand-file-name "refman/" (file-name-directory company-coq-script-full-path)))
++  (expand-file-name "@SITEETC@/refman/")
+   "Refman (and other assets)'s directory.")
+ 
+ (defface company-coq-doc-header-face-docs-and-sources
diff --git a/app-emacs/company-coq/metadata.xml b/app-emacs/company-coq/metadata.xml
new file mode 100644
index 000000000000..824f0351513e
--- /dev/null
+++ b/app-emacs/company-coq/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@gentoo.org</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>gnu-emacs@gentoo.org</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/cpitclaudel/company-coq/issues/</bugs-to>
+    <remote-id type="github">cpitclaudel/company-coq</remote-id>
+  </upstream>
+</pkgmetadata>