dev-python/irc: bump to 17.0, drops support for Python 2

Signed-off-by: Louis Sautier <sbraz@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

2 files changed, 65 insertions, 0 deletions

diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
index db17edb39ee7..9a863f4d5286 100644
--- a/dev-python/irc/Manifest
+++ b/dev-python/irc/Manifest
@@ -1,2 +1,3 @@
 DIST irc-16.3.tar.gz 87067 BLAKE2B 61d8b9cc20390a3eb918e5593a167b28f37154ee05cb4d7a72f8901509d3345e8d6bee9c17b66aa6c71fad4608a9f98eb3848190f82eac7db6f2013227979c25 SHA512 84b5a56a441cdf22396c10b81c115cb2e297ac082785e9baf0bc73d655034be1ff3f553d44412f066ab4b74530faddb66a9cc2f511a332e87fe49af0b6e68e5b
 DIST irc-16.4.tar.gz 86909 BLAKE2B c1544a36cb4173fdd22514ab5c6a61d691634224f93c9a04aa08b9fc91203aa18ed2bf429221089fd2bbea45de6138e8eb480b1ac706e36c6ed2c01405397dda SHA512 9080d3dd484751ffa80b117184cd63c4728b1bc50f2493b046a1fd3779e65016f874d0e629d2ac8a3b36db39a91985b890f3a1fb35bd9638d96f2654bf6da943
+DIST irc-17.0.tar.gz 86522 BLAKE2B 1fc1d2faa4e13bfdabffbccae0c40ea7dd477894a5b6f24370950d4bce5e833103fcd2c20d39e2fd0490975b1f36fb234bc354d08f1524062f4dfe7195158750 SHA512 7afef790048b6905d1ae1fa559fa100f57a508586a9d3641890c578730677c965b5c1dc9e00927c8178955632ff919c00484c535eaaaa5c411ce15f68a7d3f93
diff --git a/dev-python/irc/irc-17.0.ebuild b/dev-python/irc/irc-17.0.ebuild
new file mode 100644
index 000000000000..8bf685353b8a
--- /dev/null
+++ b/dev-python/irc/irc-17.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		dodoc -r scripts
+	fi
+	distutils-r1_python_install_all
+}