app-misc/geoclue: Version bump to 2.7.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/app-misc/geoclue/Manifest b/app-misc/geoclue/Manifest
index 045eab9f230a..f94eeebfc72e 100644
--- a/app-misc/geoclue/Manifest
+++ b/app-misc/geoclue/Manifest
@@ -1 +1,2 @@
 DIST geoclue-2.7.0.tar.bz2 105353 BLAKE2B b9bcf29bcdb5302d3df29f48ec235265582ec60badc4f71469faa0d100f860f943529c6a74aadec4b03cbc1474f5eab837b1b9b19ba5c7e0ab0fb6c868db727a SHA512 2314242f529b9011ee5da6e8cfc657568853769e4d38b8e7c604097a747dd5705d9f84dcd2763cdacb9f014e15b63fbb8356d6cb488ba91334cda87c11e4ee7d
+DIST geoclue-2.7.1.tar.bz2 106458 BLAKE2B a2fc44d4941936d8dcd495d77d11b0d948d7031ca048b97ff0940c7fcdd37ba604655f2e255c5e0dd5cc7a82a2d5a15b18aab4825b2446560e225c13df6da3b8 SHA512 972663a6f8c969d0e1a5f911af2b8afed486d5c0ba06dadc19bcfbe1ea22cef10243b2bd0084e5c45b70977cfa5650c8f15f760e4bc4e7dbd946745b67c9188b
diff --git a/app-misc/geoclue/geoclue-2.7.1.ebuild b/app-misc/geoclue/geoclue-2.7.1.ebuild
new file mode 100644
index 000000000000..70cf61729de9
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.7.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="A location information D-Bus service"
+HOMEPAGE="https://gitlab.freedesktop.org/geoclue/geoclue/-/wikis/home"
+SRC_URI="https://gitlab.freedesktop.org/geoclue/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+introspection gtk-doc modemmanager vala zeroconf"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/json-glib-0.14.0
+	>=net-libs/libsoup-3.0.0:3.0
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	modemmanager? ( >=net-misc/modemmanager-1.6 )
+	zeroconf? ( >=net-dns/avahi-0.6.10[dbus] )
+	x11-libs/libnotify
+"
+RDEPEND="${DEPEND}
+	acct-user/geoclue
+	sys-apps/dbus
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		>=dev-util/gtk-doc-1 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dlibgeoclue=true
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc)
+		$(meson_use modemmanager 3g-source)
+		$(meson_use modemmanager cdma-source)
+		$(meson_use modemmanager modem-gps-source)
+		$(meson_use zeroconf nmea-source)
+		-Dcompass=true
+		-Denable-backend=true
+		-Ddemo-agent=true
+		-Dsystemd-system-unit-dir="$(systemd_get_systemunitdir)"
+		-Ddbus-srv-user=geoclue
+
+		-Dmozilla-api-key=f57afde7-113f-4e8f-96d1-62be64a0273c
+	)
+
+	DISTRO="$(awk -F= '/^NAME/ {print $2}' /etc/os-release | tr -d \" )"
+	if [[ $DISTRO != Gentoo ]]; then
+		eerror "The following API key has been allocated for Gentoo only."
+		eerror "If you are a derivative, please request your own key as discussed here:"
+		eerror "https://gitlab.freedesktop.org/geoclue/geoclue/-/issues/136"
+		eerror "See also: https://location.services.mozilla.com/api and"
+		eerror "https://blog.mozilla.org/services/2019/09/03/a-new-policy-for-mozilla-location-service/"
+		die "Please request an API key for your distribution."
+	fi
+
+	meson_src_configure
+}