app-misc/radeontop: Add sys-libs/ncurses[unicode(+)]

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 57 insertions, 0 deletions

diff --git a/app-misc/radeontop/radeontop-1.3-r3.ebuild b/app-misc/radeontop/radeontop-1.3-r3.ebuild
new file mode 100644
index 000000000000..4088c077cd3b
--- /dev/null
+++ b/app-misc/radeontop/radeontop-1.3-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="Utility to view Radeon GPU utilization"
+HOMEPAGE="https://github.com/clbr/radeontop"
+SRC_URI="https://github.com/clbr/radeontop/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls video_cards_amdgpu video_cards_radeon"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_radeon )
+"
+
+RDEPEND="
+	sys-libs/ncurses:=
+	x11-libs/libdrm[video_cards_amdgpu?,video_cards_radeon?]
+	x11-libs/libpciaccess
+	x11-libs/libxcb
+	nls? (
+		sys-libs/ncurses:=[unicode(+)]
+		virtual/libintl
+	)
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	cat > include/version.h <<-EOF || die
+		#ifndef VER_H
+		#define VER_H
+
+		#define VERSION "${PV}"
+
+		#endif
+	EOF
+	>getver.sh || die
+	touch .git || die
+}
+
+src_configure() {
+	tc-export CC
+	export LIBDIR=$(get_libdir)
+	export nls=$(usex nls 1 0)
+	export amdgpu=$(usex video_cards_amdgpu 1 0)
+	export xcb=1
+	# Do not add -g or -s to CFLAGS
+	export plain=1
+}