app-misc/timew: add 1.7.1

Also adds shell completions for fish and bash. zsh completions are in
the develop branch, so I'm thinking those might get added in the next
release.

Bumps EAPI from 7 to 8 (needed for shell-completion eclass).

Signed-off-by: Ashlen <dev@anthes.is>
Closes: https://github.com/gentoo/gentoo/pull/38305
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/app-misc/timew/timew-1.7.1.ebuild b/app-misc/timew/timew-1.7.1.ebuild
new file mode 100644
index 000000000000..c8e55e30359c
--- /dev/null
+++ b/app-misc/timew/timew-1.7.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake shell-completion
+
+DESCRIPTION="Tracks your time from the command line, and generates reports"
+HOMEPAGE="https://timewarrior.net"
+SRC_URI="https://github.com/GothenburgBitFactory/timewarrior/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+src_configure() {
+	local mycmakeargs=(
+		-DTIMEW_DOCDIR=share/doc/${PF}
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${WORKDIR}"/"${P}"_build || die
+
+	eninja test
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc -r ext
+	docompress -x /usr/share/doc/${PF}/ext/{on-modify.timewarrior,README}
+
+	doman doc/man1/*.1
+	doman doc/man7/*.7
+	newbashcomp completion/timew-completion.bash timew
+	dofishcomp completion/timew.fish
+}
+
+pkg_postinst() {
+	elog "To integrate timewarrior with taskwarrior, issue the following commands:"
+	elog "cp /usr/share/doc/${PF}/ext/on-modify.timewarrior ~/.task/hooks/"
+	elog "chmod +x ~/.task/hooks/on-modify.timewarrior"
+	elog "see https://timewarrior.net/docs/taskwarrior/"
+}