app-office/scribus: 1.5.5_p20200626 snapshot bump w/ python3 support

Bug: https://bugs.gentoo.org/719938
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

3 files changed, 162 insertions, 2 deletions

diff --git a/app-office/scribus/Manifest b/app-office/scribus/Manifest
index e8d12ffa74f8..823daf4f2db2 100644
--- a/app-office/scribus/Manifest
+++ b/app-office/scribus/Manifest
@@ -1 +1,2 @@
 DIST scribus-1.5.5.tar.xz 73861836 BLAKE2B 1a10878eaba67116d72c20d8ecd8952764c709ad14d575e4eb921b4f8a7c4525b73e6722f610b1cce57c08540f619d6ebd3d32e04b653b310e475026c185561b SHA512 2d62424ad609296df33ced550940fceb4e15133a595a740cc4f4b4ffbc92aa31737336ac7716c2eed20d2866e37f5a9b780a44d86128daa6bbad3ccb58168b50
+DIST scribus-1.5.5_p20200626.tar.gz 87557791 BLAKE2B 183b035901f5a19ffbf5890acc6037eb5483a0b5837b244b39838ca03d13bd4afc76c3c41345123aec402c602177c5fff7183deba10f8e33e980659c4ef7881e SHA512 ff6cf0d86c874b7f03c8be9675f92c6cc7797e3a344326824e4f01f0b02ec02d6fdf5b52924e51b3436d9a6d78eda47a5e9987507721d18985768cc5a3c77245
diff --git a/app-office/scribus/scribus-1.5.5_p20200626.ebuild b/app-office/scribus/scribus-1.5.5_p20200626.ebuild
new file mode 100644
index 000000000000..a017d67eb016
--- /dev/null
+++ b/app-office/scribus/scribus-1.5.5_p20200626.ebuild
@@ -0,0 +1,159 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE="tk?"
+COMMIT=aa84120d97003a03d883db33ea9a6ad28550e59a
+inherit cmake desktop flag-o-matic python-single-r1 xdg
+
+DESCRIPTION="Desktop publishing (DTP) and layout program"
+HOMEPAGE="https://www.scribus.net/"
+SRC_URI="https://github.com/${PN}project/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+boost debug examples graphicsmagick hunspell +minimal osg +pdf scripts +templates tk"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	tk? ( scripts )"
+
+# osg
+# couple of third_party libs bundled
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="${PYTHON_DEPS}
+	app-text/libmspub
+	app-text/libqxp
+	app-text/poppler:=
+	dev-libs/hyphen
+	>=dev-libs/icu-58.2:0=
+	dev-libs/librevenge
+	dev-libs/libxml2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[-gles2-only]
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-libs/fontconfig
+	media-libs/freetype:2
+	>=media-libs/harfbuzz-0.9.42:0=[icu]
+	media-libs/lcms:2
+	media-libs/libcdr
+	media-libs/libfreehand
+	media-libs/libpagemaker
+	media-libs/libpng:0=
+	media-libs/libvisio
+	media-libs/libzmf
+	media-libs/tiff:0
+	net-print/cups
+	sys-libs/zlib[minizip]
+	virtual/jpeg:0=
+	>=x11-libs/cairo-1.10.0[X,svg]
+	boost? ( >=dev-libs/boost-1.67:= )
+	graphicsmagick? ( media-gfx/graphicsmagick:= )
+	hunspell? ( app-text/hunspell:= )
+	osg? ( dev-games/openscenegraph:= )
+	pdf? ( app-text/podofo:0= )
+	scripts? (
+		$(python_gen_cond_dep '
+			dev-python/pillow[tk?,${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	app-text/ghostscript-gpl
+"
+
+PATCHES=(
+	# non(?)-upstreamable
+	"${FILESDIR}"/${PN}-1.5.3-fpic.patch
+	"${FILESDIR}"/${PN}-1.5.6-docdir.patch
+	"${FILESDIR}"/${PN}-1.5.5-findhyphen-1.patch
+	"${FILESDIR}"/${PN}-1.5.6-findhyphen.patch
+)
+
+CMAKE_BUILD_TYPE="Release"
+
+S="${WORKDIR}"/${PN}-${COMMIT}
+
+src_prepare() {
+	cmake_src_prepare
+
+	rm -r codegen/cheetah scribus/third_party/hyphen || die
+
+	sed \
+		-e "/^\s*unzip\.[ch]/d" \
+		-e "/^\s*ioapi\.[ch]/d" \
+		-i scribus/CMakeLists.txt Scribus.pro || die
+	rm scribus/ioapi.[ch] || die
+
+	sed \
+		-e 's:\(${CMAKE_INSTALL_PREFIX}\):./\1:g' \
+		-i resources/templates/CMakeLists.txt || die
+
+	sed \
+		-e "/^add_subdirectory(ui\/qml)/s/^/#DONT/" \
+		-i scribus/CMakeLists.txt || die # nothing but a bogus Hello World test
+}
+
+src_configure() {
+	# bug #550818
+	append-cppflags -DHAVE_MEMRCHR
+
+	local mycmakeargs=(
+		-DHAVE_PYTHON=ON
+		-DWANT_DISTROBUILD=ON
+		-DDOCDIR="${EPREFIX}"/usr/share/doc/${PF}/
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DWITH_BOOST=$(usex boost)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_NOEXAMPLES=$(usex !examples)
+		-DWANT_GRAPHICSMAGICK=$(usex graphicsmagick)
+		-DWANT_HUNSPELL=$(usex hunspell)
+		-DWANT_HEADERINSTALL=$(usex !minimal)
+		-DWANT_NOOSG=$(usex !osg)
+		-DWITH_PODOFO=$(usex pdf)
+		-DWANT_NOTEMPLATES=$(usex !templates)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if ! use tk; then
+		rm "${ED}"/usr/share/scribus/scripts/{FontSample,CalendarWizard}.py || die
+	fi
+	if use scripts; then
+		python_fix_shebang "${ED}"/usr/share/scribus/scripts
+		python_optimize "${ED}"/usr/share/scribus/scripts
+	else
+		rm "${ED}"/usr/share/scribus/scripts/*.py || die
+	fi
+
+	mv "${ED}"/usr/share/doc/${PF}/{en,html} || die
+	ln -sf html "${ED}"/usr/share/doc/${PF}/en || die
+
+	# These files are parsed to populate the help/about window.
+	cat >> "${T}"/COPYING <<- EOF || die
+	${PN} is licensed under the "${LICENSE}".
+	Please visit https://www.gnu.org/licenses/gpl-2.0.html for the complete license text.
+	EOF
+	dodoc "${T}"/COPYING
+	docompress -x /usr/share/doc/${PF}/en /usr/share/doc/${PF}/{AUTHORS,TRANSLATION,LINKS,COPYING}
+
+	local size
+	for size in 16 32 128 256 512; do
+		newicon -s $size resources/iconsets/artwork/icon_${size}x${size}.png scribus.png
+	done
+	newicon -s 64 resources/iconsets/artwork/icon_32x32@2x.png scribus.png
+	doicon resources/iconsets/*/scribus.png
+	domenu scribus.desktop
+}
diff --git a/app-office/scribus/scribus-9999.ebuild b/app-office/scribus/scribus-9999.ebuild
index d532762422ed..944a609bb5c5 100644
--- a/app-office/scribus/scribus-9999.ebuild
+++ b/app-office/scribus/scribus-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 PYTHON_REQ_USE="tk?"
 inherit cmake desktop flag-o-matic python-single-r1 subversion xdg
 
@@ -58,8 +58,8 @@ DEPEND="${PYTHON_DEPS}
 	virtual/jpeg:0=
 	>=x11-libs/cairo-1.10.0[X,svg]
 	boost? ( >=dev-libs/boost-1.67:= )
-	hunspell? ( app-text/hunspell:= )
 	graphicsmagick? ( media-gfx/graphicsmagick:= )
+	hunspell? ( app-text/hunspell:= )
 	osg? ( dev-games/openscenegraph:= )
 	pdf? ( app-text/podofo:0= )
 	scripts? (