dev-libs/cyberjack: version bump (adds support for cyberJack one)

Package-Manager: Portage-2.3.8, Repoman-2.3.1

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-libs/cyberjack/Manifest b/dev-libs/cyberjack/Manifest
index 8894ba6b3b42..736bc95241ac 100644
--- a/dev-libs/cyberjack/Manifest
+++ b/dev-libs/cyberjack/Manifest
@@ -1,2 +1,3 @@
 DIST pcsc-cyberjack-3.99.5final.SP10.tar.bz2 958494 SHA256 910ac025b504a0407cee3d9f8a77655f3007871591113054bedede5f1aeae958 SHA512 d4094b531ab523db29856ea0cf784db925bece51a5c4b5c7fec259ff319d58a50443cabdfebc0a1f6818b678a1284500429274478bf1db780ff594612e307d56 WHIRLPOOL 8a80cbd2dc8e3597f169a0a16c963c4b02faba2909639c2a5affe85098cf4c63e244ed5076477b7b5032e446097c24da07dfc88fc1a68a9f48a64624d3a6cbc0
+DIST pcsc-cyberjack-3.99.5final.SP11.tar.bz2 965662 SHA256 5cd78f527596f2905500b210d066ece62a8ab36a0d4d3677463805f8f4d3aa0c SHA512 4d63ef0442c7e919456e8b6ab1d571ab621eb45fc34fc9b61a7a024f1ae2115f7474b4aa538ee7fb8bf4ce016067c876d9970b52e6b4e8b531e2d736677ab794 WHIRLPOOL 541e0cf4dc24848d1f2bd66f0fab2745b955610dc4d9f31dfac080341df2b2ea4362b4da4020d1a9b813437b3a6b3e835ae04e70923cf6b3a14b172aa01340ff
 DIST pcsc-cyberjack_3.99.5final.SP03.tar.gz 1485952 SHA256 fa5324d8a270d50aec20345cb57362f684ddadd3a50dbd0773ee13d2d87bc0a9 SHA512 a091a09b501d7a7c757f0a458007f44ac281cbeaaf5bc3c2aa89915ee7a39478e6f80b6f24fec77be753c8d77deeda2858b7a806e3c982f54c199bd797288e05 WHIRLPOOL 51429512a9037e6ec4a98cc33576176cafda5fe3a3b33c56b2d928c7a7bc06135ac93e92a713836e4dc20e90f6106f9ca3643de5baed7c25672c26f6fc4a6368
diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p11.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p11.ebuild
new file mode 100644
index 000000000000..23447ead9e43
--- /dev/null
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p11.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools versionator eutils linux-info toolchain-funcs udev
+
+MY_PV="${PV/_p/_SP}"
+MY_PV2="${PV/_p/final.SP}"
+MY_P="pcsc-${PN}-${MY_PV2}"
+#MY_P2="${PN}-$(get_version_component_range 4 $MY_PV)"
+
+DESCRIPTION="REINER SCT cyberJack pinpad/e-com USB user space driver library"
+HOMEPAGE="http://www.reiner-sct.de/"
+SRC_URI="http://support.reiner-sct.de/downloads/LINUX/V${MY_PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs threads +udev +usb"
+
+# FIXME:
+# xml is actually optional but the code is still used anyway. We'll have to wait
+# until upstream fixed it.
+COMMON_DEPEND="sys-apps/pcsc-lite
+	usb? ( virtual/libusb:1 )"
+RDEPEND="${COMMON_DEPEND}
+	udev? ( virtual/udev )"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+#S=${WORKDIR}/${MY_P2}
+S=${WORKDIR}/${MY_P}
+
+DOCS="debian/changelog doc/README.txt"
+
+pkg_setup() {
+	CONFIG_CHECK="~USB_SERIAL_CYBERJACK"
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-manpages.patch"
+	epatch "${FILESDIR}/${PN}-returnvalue.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/${PN} \
+		--disable-hal \
+		--enable-pcsc \
+		$(use_enable static-libs static) \
+		$(use_enable usb nonserial) \
+		$(use_enable threads) \
+		--with-usbdropdir="$($(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir)"
+}
+
+src_install() {
+	default
+
+	prune_libtool_files --all
+
+	use udev && udev_newrules "${FILESDIR}"/${PN}-r1.rules 92-${PN}.rules #388329
+}
+
+pkg_postinst() {
+	local conf="${EROOT}etc/${PN}/${PN}.conf"
+	elog
+	elog "To configure logging, key beep behaviour etc. you need to"
+	elog "copy ${conf}.default"
+	elog "to ${conf}"
+	elog "and modify the latter as needed."
+	elog
+}