dev-libs/libtommath: bump to 1.2.0

Closes: https://bugs.gentoo.org/723854
Closes: https://bugs.gentoo.org/641184
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 80 insertions, 0 deletions

diff --git a/dev-libs/libtommath/libtommath-1.2.0.ebuild b/dev-libs/libtommath/libtommath-1.2.0.ebuild
new file mode 100644
index 000000000000..c1ed57ebc347
--- /dev/null
+++ b/dev-libs/libtommath/libtommath-1.2.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Optimized and portable routines for integer theoretic applications"
+HOMEPAGE="http://www.libtom.net/"
+SRC_URI="https://github.com/libtom/libtommath/releases/download/v${PV}/ltm-${PV}.tar.xz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc examples static-libs"
+
+src_prepare() {
+	default
+
+	# need libtool for cross compilation. Bug #376643
+	cat <<-EOF > configure.ac
+	AC_INIT(libtommath, 0)
+	AM_INIT_AUTOMAKE
+	LT_INIT
+	AC_CONFIG_FILES(Makefile)
+	AC_OUTPUT
+	EOF
+
+	touch NEWS README AUTHORS ChangeLog Makefile.am
+
+	eautoreconf
+	export LIBTOOL="${S}"/libtool
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+_emake() {
+	emake \
+		CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" \
+		RANLIB="$(tc-getRANLIB)" \
+		IGNORE_SPEED=1 \
+		DESTDIR="${ED}" \
+		LIBPATH="/usr/$(get_libdir)" \
+		INCPATH="/usr/include" \
+		"$@"
+}
+
+src_compile() {
+	_emake -f makefile.shared
+}
+
+src_test() {
+	# Tests must be built statically
+	# (i.e. without -f makefile.shared)
+	_emake test
+
+	./test || die
+}
+
+src_install() {
+	_emake -f makefile.shared install
+
+	# We only link against -lc, so drop the .la file.
+	find "${ED}" -name '*.la' -delete || die
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+
+	dodoc changes.txt
+
+	use doc && dodoc doc/*.pdf
+
+	if use examples ; then
+		docinto demo
+		dodoc demo/*.c
+	fi
+}