dev-libs/libxmlb: add 0.3.11

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-libs/libxmlb/libxmlb-0.3.11.ebuild b/dev-libs/libxmlb/libxmlb-0.3.11.ebuild
new file mode 100644
index 000000000000..62d8c5c5817f
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.3.11.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # libxmlb.so version
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc introspection stemmer test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/xz-utils
+	app-arch/zstd:=
+	dev-libs/glib:2
+	sys-apps/util-linux
+	stemmer? ( dev-libs/snowball-stemmer:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.3.9-no_installed_tests.patch
+)
+
+python_check_deps() {
+	python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc gtkdoc)
+		$(meson_use introspection)
+		$(meson_use stemmer)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}