dev-libs/xqilla: Version bump to 2.3.3

Gentoo-bug: 593940
* EAPI=6

Package-Manager: portage-2.3.0

2 files changed, 73 insertions, 0 deletions

diff --git a/dev-libs/xqilla/Manifest b/dev-libs/xqilla/Manifest
index cc91e6fe0443..3d52cde3965c 100644
--- a/dev-libs/xqilla/Manifest
+++ b/dev-libs/xqilla/Manifest
@@ -1,2 +1,3 @@
 DIST XQilla-2.2.4.tar.gz 15667750 SHA256 f39f8d11bca67ded2036d543bb6780ebeeee5b5723d75f067f256ae26516854b SHA512 2071377519846d131fc7dc5b97ddf653763e898921490278200be1be48464d67e6466af2a447b266f952a2af2b1eac2febc33c0d4aca0cbefe9672ced42d5f14 WHIRLPOOL ccf294529721035d8995438a905c401c7de43e3f72c7ed27b8b0d347a818459a784b37e3f84ebc221b2583959a869b8d6d76d694a1b1e5318ba9eff53229c53a
 DIST XQilla-2.3.0.tar.gz 7409736 SHA256 60e163cbbbe2900f999ee863bfa5a63d913b1d6e2ea17376302d565d2e9e1bc7 SHA512 cd9b8ce8f44b307ea17ed8d2507d811eca6c69a425341bea568719ef3468840f713f4e5fc3abf61e27cdcc01c2c834fb3745730bb2244777388f293c9d2723ac WHIRLPOOL 6ec8c0b8d88087b813071138c5652bd6cd31664108c06f34b0a80b3ab3c987332106a4e60c18c43fa6798f0ace1756945d7a0c4c6849e4a3b816736e8afcb586
+DIST XQilla-2.3.3.tar.gz 16170903 SHA256 8f76b9b4f966f315acc2a8e104e426d8a76ba4ea3441b0ecfdd1e39195674fd6 SHA512 5a27416eaf1d7120c42dbd5c737e112954d4e3782de5ff4c77e29f1bcd1a5712cdc5a76f707d9c3323526a361e46df98d8ee1ca87c760d389d85598a8265054f WHIRLPOOL b95d1df9ad5934f5784cad88fc1a2c0d498b07d95e0cb1f5a537a8a3a6318702fbfaa148f665e6d68160feb0353051b85f21f693be18654b16de5e20545b0a83
diff --git a/dev-libs/xqilla/xqilla-2.3.3.ebuild b/dev-libs/xqilla/xqilla-2.3.3.ebuild
new file mode 100644
index 000000000000..25ddf5da4889
--- /dev/null
+++ b/dev-libs/xqilla/xqilla-2.3.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools
+
+MY_P="XQilla-${PV}"
+
+DESCRIPTION="An XQuery and XPath 2 library and command line utility written in C++"
+HOMEPAGE="http://xqilla.sourceforge.net/HomePage"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+LICENSE="Apache-2.0 BSD"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples faxpp htmltidy static-libs"
+
+# XQilla bundles two libraries:
+# - mapm, heavily patched
+# - yajl, moderately patched
+# There's currently no way to unbundle those
+
+RDEPEND=">=dev-libs/xerces-c-3.1.1
+	faxpp? ( dev-libs/faxpp )
+	htmltidy? ( app-text/htmltidy )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}/2.2.4-respect-ldflags-no-rpath.patch"
+)
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-xerces="${EPREFIX}"/usr \
+		$(use_enable debug) \
+		$(use_with htmltidy tidy /usr) \
+		$(use_with faxpp faxpp /usr) \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+	use doc && emake docs devdocs
+}
+
+src_install () {
+	use doc && HTML_DOCS=( docs/{dev-api,dom3-api,simple-api} )
+	default
+
+	if ! use static-libs; then
+		find "${D}" -name '*.la' -delete || die
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc -r "${S}"/src/samples/.
+	fi
+
+	# remove unnecessary files previously filtered by dohtml
+	find "${ED%/}/usr/share/doc/${PF}" \
+		\( -name '*.map' -o -name '*.md5' \) -delete || die
+}