dev-php/PEAR-Var_Dump: new EAPI=6 revision sans the php-pear-r1 eclass.

With our own (non-eclass) src_install, we actually install the docs in
the correct place. I've added a test suite but was forced to restrict
it because of some deprecation warnings.

Package-Manager: portage-2.3.0

2 files changed, 44 insertions, 22 deletions

diff --git a/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r1.ebuild b/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r1.ebuild
deleted file mode 100644
index 19808a203445..000000000000
--- a/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r1.ebuild
+++ /dev/null
@@ -1,22 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-inherit php-pear-r1
-
-DESCRIPTION="Provides methods for dumping structured information about a variable"
-
-LICENSE="PHP-3.01"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE=""
-DEPEND=">=dev-lang/php-5.3"
-RDEPEND="${DEPEND}"
-
-src_install() {
-	php-pear-r1_src_install
-	# Remove the documenation generation binary that is specific to this package
-	rm "${D}usr/bin/gen_php_doc.sh" || die
-}
diff --git a/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r2.ebuild b/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r2.ebuild
new file mode 100644
index 000000000000..edce450e670d
--- /dev/null
+++ b/dev-php/PEAR-Var_Dump/PEAR-Var_Dump-1.0.4-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PN="${PN/PEAR-/}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Dump structured information about a variable"
+HOMEPAGE="http://pear.php.net/package/${MY_PN}"
+SRC_URI="http://download.pear.php.net/package/${MY_P}.tgz"
+LICENSE="PHP-3.01"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples test"
+
+RDEPEND="dev-lang/php:*
+	dev-php/PEAR-PEAR"
+DEPEND="test? ( ${RDEPEND} )"
+
+S="${WORKDIR}/${MY_P}"
+
+# The test suite fails due to some deprecation warnings that are output.
+# The test cases themselves set error_reporting(E_ALL), so there's no
+# easy way to override it.
+RESTRICT=test
+
+src_install() {
+	use examples && dodoc -r docs/example*.php
+
+	insinto /usr/share/php
+	doins "${MY_PN}.php"
+	doins -r "${MY_PN}"
+}
+
+src_test() {
+	# Requires the "pear" executable from dev-php/PEAR-PEAR.
+	pear run-tests tests || die
+
+	# The command succeeds regardless of whether or not the test suite
+	# passed, but this file is only written when there was a failure.
+	[[ -f run-tests.log ]] && die "test suite failed"
+}