dev-python/aws-xray-sdk-python: add 2.12.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-python/aws-xray-sdk-python/Manifest b/dev-python/aws-xray-sdk-python/Manifest
index 31d38d10493a..ae7bae43d8f9 100644
--- a/dev-python/aws-xray-sdk-python/Manifest
+++ b/dev-python/aws-xray-sdk-python/Manifest
@@ -1 +1,2 @@
 DIST aws-xray-sdk-python-2.11.0.gh.tar.gz 275430 BLAKE2B 1c1d3b56629dbd822b4f9fcb1e7ba5b43fbbff55fbe7ac02d75e0bb50629c4a0e5baed2b4c14c4c8a7775d60da5b285f96bca68b68b64ddf03aeec0c6094c74c SHA512 62035db955ce3d60e6d75088b7255dec83b21b4fd02353146b34bc48bdacff805b711b5caaca7adbbb5c5a3632a97910907d04681f36c198c99fbb4ef1cc4f85
+DIST aws-xray-sdk-python-2.12.0.gh.tar.gz 275773 BLAKE2B a78ac201524e70a342100c2e76e93bb02ed76e183dfca2e8737230061182d94c9a7f4eba183bc731d2ed79a8e4dda486ea09cb304f4cd58da56d712b8e6c5749 SHA512 0616369f95bf0de710ab5fb868d1a84280bcc1180cc205e6a6e0c405eae131fb861de75fea00c9c1be4e163b9d292cc27e08f624c7b6981ba4a3b8d99dbbb63c
diff --git a/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.12.0.ebuild b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.12.0.ebuild
new file mode 100644
index 000000000000..610caf67ed1f
--- /dev/null
+++ b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.12.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="
+	https://github.com/aws/aws-xray-sdk-python/
+	https://pypi.org/project/aws-xray-sdk/
+"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		<dev-python/flask-sqlalchemy-3[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-2[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local EPYTEST_DESELECT=(
+		# Internet access
+		tests/test_patcher.py::test_external_file
+		tests/test_patcher.py::test_external_module
+		tests/test_patcher.py::test_external_submodules_full
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		# benchmark
+		tests/test_local_sampling_benchmark.py
+		# Fails, probably because above is ignored
+		tests/test_async_local_storage.py::test_localstorage_isolation
+		tests/test_async_recorder.py::test_capture
+		tests/test_async_recorder.py::test_concurrent_calls
+		tests/test_async_recorder.py::test_async_context_managers
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged deps
+		tests/ext/aiobotocore
+		tests/ext/pg8000
+		tests/ext/psycopg2
+		tests/ext/pymysql
+		tests/ext/pynamodb
+		tests/ext/sqlalchemy_core/test_postgres.py
+		tests/ext/django/test_db.py
+		# Internet access
+		tests/ext/httplib
+		tests/ext/httpx
+		tests/ext/requests
+		# requires old package vesions
+		tests/ext/django
+		tests/ext/aiohttp
+	)
+
+	epytest -p no:django
+}