dev-python/http-parser: Bump to 0.9.0

Closes: https://bugs.gentoo.org/723556
Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/http-parser/http-parser-0.9.0.ebuild b/dev-python/http-parser/http-parser-0.9.0.ebuild
new file mode 100644
index 000000000000..5a0b335f0ccb
--- /dev/null
+++ b/dev-python/http-parser/http-parser-0.9.0.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{6,7,8}} )
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP request/response parser for python in C"
+HOMEPAGE="https://github.com/benoitc/http-parser"
+SRC_URI="
+	https://github.com/benoitc/http-parser/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	if [[ ${EPYTHON} != python3* ]]; then
+		local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_install_all() {
+	local DOCS=( README.rst )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}