dev-python/plotly: Bump to 5.17.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 117 insertions, 0 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index dc60ecdf0cae..ae60699530e5 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1,3 +1,4 @@
 DIST plotly.py-5.15.0.gh.tar.gz 30801940 BLAKE2B bb95df7402a308c1a32817dc12d519a446f63cfe34f6a6c492949465734132a2d86078849790ee51d6cb99fbaf434251c48204e0b2b36af422fdf7efbc446a6a SHA512 418f05fd6eb17de3619c647ba83817144d8b9f7eec766cae492fb9987ad1e5ff169cfe045d163997916bdf0df75dafba94fb55c68a5dfb45c8aa87cb3e0e4658
 DIST plotly.py-5.16.0.gh.tar.gz 30846584 BLAKE2B 08071fbece2ac6ce69ae7466a001902867883127e7bfab397d5701eee0afc032fdc001157b4e38d4cbe9bfe361e18f7c33cc0e80b21d8deba5219821849848ab SHA512 2cbdc04a62de803d06d4085180caeaea9a7c429d525e841472a6b4a447dd53ab108e159a9b28ddcbcf86a47453ed028ad6d3d47001e3d68286aded4b10b1511b
 DIST plotly.py-5.16.1.gh.tar.gz 30846702 BLAKE2B 75985b37e56b4612f8c0bcd249d1a27e43d2f531715802f1d80c9f83b7536f4a124ffb0355cdee3db64e02feede2a37bcfca58b20e5fdad50e31c66291eb0181 SHA512 dabbbfe0da26b675fc30a8e3a9e105b13589a9906df11cbcae2f8fbaadf59e694ae1864de329665acebeabcb8821f1425d7b3cb3ffd96522d376e8d3b7704afa
+DIST plotly.py-5.17.0.gh.tar.gz 30874848 BLAKE2B 3a2bb0a38538372299f706f1ab45b6e51b2b27304c05328c0fda8f2b74c3f7f2ecacfd1aa5cdb4abb5f6890ab636d807e507bda8354ab19018f2282950d2eb5f SHA512 bde92fdd8afa218ff9090ab84afdd49ece4a67171b3e6c0148318a2e953e598d4401e52a2ca44894d8fc67382232bdf26cc340d03e7209a93c2fb4d3bed70810
diff --git a/dev-python/plotly/plotly-5.17.0.ebuild b/dev-python/plotly/plotly-5.17.0.ebuild
new file mode 100644
index 000000000000..fb5d7588cae8
--- /dev/null
+++ b/dev-python/plotly/plotly-5.17.0.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/packages/python/plotly"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		sci-libs/scikit-image[${PYTHON_USEDEP}]
+	)
+"
+
+# README ends up a broken symlink
+DOCS=()
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.8.0-fix-versioneer-import.patch
+)
+
+EPYTEST_IGNORE=(
+	# Needs porting to newer numpy
+	_plotly_utils/tests/validators/test_integer_validator.py
+
+	# kaleido not packaged
+	plotly/tests/test_optional/test_kaleido
+
+	# plotly-orca not packaged
+	plotly/tests/test_orca
+)
+
+EPYTEST_DESELECT=(
+	# Also needs porting to newer numpy
+	plotly/tests/test_io/test_to_from_plotly_json.py::test_object_numpy_encoding
+
+	# kaleido not packaged
+	plotly/tests/test_orca/test_to_image.py::test_bytesio
+
+	# Fails if not already installed
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# Minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_path_collection
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# In python 3.11 the produced error is slightly different
+	plotly/tests/test_core/test_errors/test_dict_path_errors.py::test_described_subscript_error_on_type_error
+
+	# TODO
+	plotly/tests/test_io/test_to_from_plotly_json.py
+
+	# two subtests that require 'vaex' and 'polars' respectively
+	plotly/tests/test_optional/test_px/test_px_input.py::test_build_df_from_vaex_and_polars
+	plotly/tests/test_optional/test_px/test_px_input.py::test_build_df_with_hover_data_from_vaex_and_polars
+)
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	mv "${ED}"/{usr/etc,etc} || die
+}