dev-python/sympy: Bump to 1.13.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 106 insertions, 0 deletions

diff --git a/dev-python/sympy/Manifest b/dev-python/sympy/Manifest
index 9b42f9be6868..2ddd57caa73f 100644
--- a/dev-python/sympy/Manifest
+++ b/dev-python/sympy/Manifest
@@ -1 +1,2 @@
 DIST sympy-1.13.2.gh.tar.gz 8141028 BLAKE2B 7a51fa75f1733364d467b79174b71ba866751399d311212144fdc3abdc8cea99618baf0b0fe3f2fe4cb9ab7153ecae4fe4bf00716e97ea4466637633f5618089 SHA512 87f7da425ed577e78392671cb635c99a11f3d6431b8c49a41611f4d2be5da1cadd8d07e0e684f2674792a2ee750b4031baec53156e7192d4c47714d4537c3222
+DIST sympy-1.13.3.gh.tar.gz 7919933 BLAKE2B 94c601e79caf87eb0f08e15ca4cb79e16bcd97d347e1fd948b6ea98b044133ea99f52032f09e290668e4485393425254ff4062ccfd3a3ac0b8afba080da6ba19 SHA512 2ae7a400d4a2d9c826cfaa165e3e1f5d9ba210c25647984d997775d4ec3d7c8f3ad3c5468d9adf141a1dceec864ca988b4f3a01fd934b923c4486ddd458670a3
diff --git a/dev-python/sympy/sympy-1.13.3.ebuild b/dev-python/sympy/sympy-1.13.3.ebuild
new file mode 100644
index 000000000000..b86ea4f35e26
--- /dev/null
+++ b/dev-python/sympy/sympy-1.13.3.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Computer Algebra System in pure Python"
+HOMEPAGE="
+	https://www.sympy.org/
+	https://github.com/sympy/sympy/
+	https://pypi.org/project/sympy/
+"
+# pypi sdist misses some files, notably top-level conftest.py, as of 1.12.1_rc1
+SRC_URI="
+	https://github.com/sympy/sympy/archive/${PV/_/}.tar.gz
+		-> ${P/_/}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="imaging ipython latex mathml opengl pdf png pyglet symengine texmacs"
+
+RDEPEND="
+	>=dev-python/mpmath-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	imaging? ( dev-python/pillow[${PYTHON_USEDEP}] )
+	ipython? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+	)
+	latex? (
+		virtual/latex-base
+		dev-texlive/texlive-fontsextra
+		png? ( app-text/dvipng )
+		pdf? ( app-text/ghostscript-gpl )
+	)
+	mathml? ( dev-python/lxml[${PYTHON_USEDEP}] )
+	opengl? ( dev-python/pyopengl[${PYTHON_USEDEP}] )
+	pyglet? ( dev-python/pyglet[${PYTHON_USEDEP}] )
+	symengine? ( dev-python/symengine[${PYTHON_USEDEP}] )
+	texmacs? ( app-office/texmacs )
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# TODO; virtx?
+		sympy/plotting/pygletplot
+	)
+	local EPYTEST_DESELECT=(
+		# require old version of antlr4
+		sympy/parsing/tests/test_autolev.py
+		sympy/parsing/tests/test_latex.py
+		# crash due to assertions in sys-devel/llvm[debug]
+		sympy/parsing/tests/test_c_parser.py
+
+		# TODO: pytest?
+		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_check
+		sympy/solvers/ode/tests/test_systems.py::test_linear_3eq_order1_type4_long_dsolve_dotprodsimp
+
+		# either very slow or hanging
+		sympy/solvers/ode/tests/test_systems.py::test_linear_new_order1_type2_de_lorentz_slow_check
+		sympy/integrals/tests/test_failing_integrals.py::test_issue_15227
+		sympy/matrices/tests/test_matrices.py::test_pinv_rank_deficient_when_diagonalization_fails
+		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type1
+		sympy/solvers/ode/tests/test_systems.py::test_nonlinear_3eq_order1_type3
+
+		# known broken
+		# https://github.com/sympy/sympy/issues/26321
+		sympy/solvers/tests/test_simplex.py::test_lp
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest --veryquickcheck ||
+		die -n "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.md )
+
+	distutils-r1_python_install_all
+
+	if use texmacs; then
+		exeinto /usr/libexec/TeXmacs/bin/
+		doexe data/TeXmacs/bin/tm_sympy
+		insinto /usr/share/TeXmacs/plugins/sympy/
+		doins -r data/TeXmacs/progs
+	fi
+}