dev-python/zipp: bump to 3.1.0

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/zipp/zipp-3.1.0.ebuild b/dev-python/zipp/zipp-3.1.0.ebuild
new file mode 100644
index 000000000000..c3effeb47ea0
--- /dev/null
+++ b/dev-python/zipp/zipp-3.1.0.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+# [options.entry_points] is present in setup.cfg but it is empty
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
+HOMEPAGE="https://github.com/jaraco/zipp"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="test"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-3.4.2[${PYTHON_USEDEP}]
+	test? ( dev-python/jaraco-itertools[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	">=dev-python/jaraco-packaging-3.2" \
+	">=dev-python/rst-linker-1.9"
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Skip a potentially flaky performance test
+	sed -i -e '/^import func_timeout\|^ *@func_timeout\.func_set_timeout/d' \
+		-e 's/test_implied_dirs_performance/_&/' test_zipp.py || die
+	distutils-r1_python_prepare_all
+}