dev-python/isort: add 5.11.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/dev-python/isort/Manifest b/dev-python/isort/Manifest
index fd4260d7faa5..5aac182706cb 100644
--- a/dev-python/isort/Manifest
+++ b/dev-python/isort/Manifest
@@ -1 +1,2 @@
 DIST isort-5.10.1.gh.tar.gz 728462 BLAKE2B 5b892b9849293e8730e6d89592bace62009a8589d185b4d3a5bafded605ccd46fd0f2986fbad5cf1d72321d030e3193a111ab7e6114c6b4a7a67696f546b3a14 SHA512 545c1844bacc1d2d9e87e60b03b30a846ee1ebbfe2a229c3e018a2e1cc6e9a04a3691f1b2e7ec8575806f2341bc1af15eb64904b4eabd786d6b9b289cea5ce2a
+DIST isort-5.11.1.gh.tar.gz 731273 BLAKE2B 9044579ae53df64b78762384eba9b329017c12a1e8208382b56fa76a0d54443379b17463ff547f014d18b0bc06a9d1382b4a7e3c7a44c6a6ada1a8ed836460eb SHA512 0d891bb0b546d01a4bb5ca4f8f62683c8864b396e2c15549b5f40da4c3b630ae9100026f95c7be78aae2e3238e9d173fdb08ea9eca519631f7dea64e0643d4d1
diff --git a/dev-python/isort/isort-5.11.1.ebuild b/dev-python/isort/isort-5.11.1.ebuild
new file mode 100644
index 000000000000..bd9a3933387a
--- /dev/null
+++ b/dev-python/isort/isort-5.11.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A python utility/library to sort imports"
+HOMEPAGE="
+	https://github.com/PyCQA/isort/
+	https://pypi.org/project/isort/
+"
+SRC_URI="
+	https://github.com/PyCQA/isort/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/tomli[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/black[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/pylama[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unbundle tomli
+	sed -i -e 's:from ._vendored ::' isort/settings.py || die
+	rm -r isort/_vendored || die
+	# leftover toml import used to determine .toml support
+	sed -i -e 's:import toml:toml = True:' tests/unit/test_isort.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Install necessary plugins
+	local p
+	for p in example*/; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local EPYTEST_IGNORE=(
+		# Excluded from upstream's test script
+		tests/unit/test_deprecated_finders.py
+	)
+	epytest tests/unit
+}