games-arcade/barbarian-bin: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 53 insertions, 47 deletions

diff --git a/games-arcade/barbarian-bin/barbarian-bin-1.01-r1.ebuild b/games-arcade/barbarian-bin/barbarian-bin-1.01-r1.ebuild
deleted file mode 100644
index 555f99dd3acb..000000000000
--- a/games-arcade/barbarian-bin/barbarian-bin-1.01-r1.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-MY_PN=${PN/-bin/}
-DESCRIPTION="Save Princess Mariana through one-on-one battles with demonic barbarians"
-HOMEPAGE="http://www.tdbsoft.com/"
-SRC_URI="http://www.pcpages.com/tomberrr/downloads/${MY_PN}${PV/./}_linux.zip"
-
-LICENSE="CC-BY-NC-ND-2.0"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-RESTRICT="strip"
-IUSE=""
-
-DEPEND="app-arch/unzip"
-RDEPEND="sys-libs/libstdc++-v3:5
-	amd64? ( sys-libs/libstdc++-v3:5[multilib] )
-	>=media-libs/libsdl-1.2.15-r4[abi_x86_32(-)]"
-
-game_dest="${GAMES_PREFIX_OPT}/${MY_PN}"
-QA_PREBUILT="${game_dest:1}/Barbarian"
-
-S=${WORKDIR}
-
-src_install() {
-	dodir "${game_dest}"
-	cp -r gfx sounds "${D}${game_dest}/" || die
-
-	exeinto "${game_dest}"
-	doexe Barbarian
-
-	dohtml Barbarian.html
-
-	games_make_wrapper barbarian ./Barbarian "${game_dest}"
-
-	# High-score file
-	dodir "${GAMES_STATEDIR}"
-	touch "${D}${GAMES_STATEDIR}/heroes.hoh"
-	fperms 660 "${GAMES_STATEDIR}/heroes.hoh"
-	dosym "${GAMES_STATEDIR}/heroes.hoh" "${game_dest}/heroes.hoh"
-	newicon gfx/sprites/player_attack_2_1.bmp barbarian.bmp
-	make_desktop_entry barbarian "Barbarian" /usr/share/pixmaps/barbarian.bmp
-	prepgamesdirs
-}
diff --git a/games-arcade/barbarian-bin/barbarian-bin-1.01-r2.ebuild b/games-arcade/barbarian-bin/barbarian-bin-1.01-r2.ebuild
new file mode 100644
index 000000000000..c7f7f26b27fe
--- /dev/null
+++ b/games-arcade/barbarian-bin/barbarian-bin-1.01-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop wrapper
+
+MY_PN=${PN/-bin/}
+DESCRIPTION="Save Princess Mariana through one-on-one battles with demonic barbarians"
+HOMEPAGE="http://www.tdbsoft.com/"
+SRC_URI="http://www.pcpages.com/tomberrr/downloads/${MY_PN}${PV/./}_linux.zip"
+S="${WORKDIR}"
+
+LICENSE="CC-BY-NC-ND-2.0"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="strip"
+
+RDEPEND="
+	acct-group/gamestat
+	>=media-libs/libsdl-1.2.15-r4[abi_x86_32(-)]
+	sys-libs/libstdc++-v3:5
+	amd64? ( sys-libs/libstdc++-v3:5[multilib] )
+"
+BDEPEND="app-arch/unzip"
+
+game_dest="opt/${MY_PN}"
+QA_PREBUILT="${game_dest}/Barbarian"
+
+src_install() {
+	dodir ${game_dest}
+	cp -r gfx sounds "${ED}"/${game_dest}/ || die
+
+	exeinto ${game_dest}
+	doexe Barbarian
+
+	docinto html
+	dodoc Barbarian.html
+
+	make_wrapper barbarian ./Barbarian "${game_dest}"
+
+	# High-score file
+	dodir /var/games/${PN}
+	touch "${ED}"/var/games/${PN}/heroes.hoh || die
+	dosym ../../var/games/${PN}/heroes.hoh ${game_dest}/heroes.hoh
+
+	fperms 660 /var/games/${PN}/heroes.hoh
+	fowners -R root:gamestat /var/games/${PN}
+	fperms g+s /opt/${MY_PN}/Barbarian
+
+	newicon gfx/sprites/player_attack_2_1.bmp barbarian.bmp
+	make_desktop_entry barbarian "Barbarian" /usr/share/pixmaps/barbarian.bmp
+}