games-simulation/openttd: update to 12.0

Migrated to EAPI=8, updated dependencies, fixed bugs.
Regarding #807364, there will be always unused CMAKE_DISABLE_FIND_PACKAGE_SDL
warning since it will be used when USE="allegro -sdl", other unused
variables are fixed.

Closes: https://bugs.gentoo.org/807364
Closes: https://bugs.gentoo.org/810538
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/games-simulation/openttd/Manifest b/games-simulation/openttd/Manifest
index e1bd78d5f722..cb5324009a43 100644
--- a/games-simulation/openttd/Manifest
+++ b/games-simulation/openttd/Manifest
@@ -1 +1,2 @@
 DIST openttd-1.11.2-source.tar.xz 6783972 BLAKE2B c71fd98a480566aede29f84afbd100b6d0dfa80311860907a7287d2d5bed74bd492c2b1012cd83f45fe68d60fb0c2378e1384530a84c28bd7fbd907b45110491 SHA512 9a6364bf19627db9f8ec58bfa85fa3a8febf1109f3b5fb9053bef810ac2d0c41df91b58f0b253dd45320a29cae2e8485df794afa7b5240f19759f98fd65c35ea
+DIST openttd-12.0-source.tar.xz 7307832 BLAKE2B 12ffd0978e1f735f4a1d9eb63876a6f4a38867f11e5cbfbb7386f34564ef8b79f394b782c99f28e8a65196b7311aee28427d0485abd2e16dd69f36beb40fa3b1 SHA512 a1042fe52892cf301d3a2c7e972d9c091829638119d2ca9b55165a6b5568660f178e808db4b0bf2d3e4538dbdaea7b0683d4de9333defbcd95e109d591c05a78
diff --git a/games-simulation/openttd/openttd-12.0.ebuild b/games-simulation/openttd/openttd-12.0.ebuild
new file mode 100644
index 000000000000..73990ea5a054
--- /dev/null
+++ b/games-simulation/openttd/openttd-12.0.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="A clone of Transport Tycoon Deluxe"
+HOMEPAGE="https://www.openttd.org/"
+SRC_URI="https://cdn.openttd.org/openttd-releases/${PV}/${P}-source.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+IUSE="allegro cpu_flags_x86_sse dedicated +fluidsynth icu +lzma lzo +openmedia +png +sdl timidity +truetype +zlib"
+REQUIRED_USE="!dedicated? ( || ( allegro sdl ) )"
+
+RESTRICT="test" # needs a graphics set in order to test
+
+RDEPEND="
+	!dedicated? (
+		allegro? ( media-libs/allegro:5 )
+		fluidsynth? ( media-sound/fluidsynth )
+		icu? (
+			dev-libs/icu-layoutex:=
+			dev-libs/icu-le-hb
+			>=dev-libs/icu-58.1:=
+		)
+		sdl? ( media-libs/libsdl2[sound,video] )
+		truetype? (
+			media-libs/fontconfig
+			media-libs/freetype:2
+			sys-libs/zlib:=
+		)
+	)
+	lzma? ( app-arch/xz-utils )
+	lzo? ( dev-libs/lzo:2 )
+	png? ( media-libs/libpng:0= )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}"
+BDEPEND=">=games-util/grfcodec-6.0.6_p20210310
+	virtual/pkgconfig"
+PDEPEND="
+	!dedicated? (
+		openmedia? (
+			>=games-misc/openmsx-0.4.0
+			>=games-misc/opensfx-1.0.1
+		)
+	)
+	openmedia? ( >=games-misc/opengfx-0.6.1 )
+	timidity? ( media-sound/timidity++ )"
+
+DOCS=( docs/directory_structure.md )
+PATCHES=(
+	"${FILESDIR}/${PN}-1.11.2_dont_compress_man.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_BINDIR=bin
+		-DCMAKE_INSTALL_DATADIR=share
+		-DOPTION_DEDICATED=$(usex dedicated)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Allegro=$(usex !allegro)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Freetype=$(usex !truetype)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Fontconfig=$(usex !truetype)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Fluidsynth=$(usex !fluidsynth)
+		-DCMAKE_DISABLE_FIND_PACKAGE_ICU=$(usex !icu)
+		-DCMAKE_DISABLE_FIND_PACKAGE_LibLZMA=$(usex !lzma)
+		-DCMAKE_DISABLE_FIND_PACKAGE_LZO=$(usex !lzo)
+		-DCMAKE_DISABLE_FIND_PACKAGE_PNG=$(usex !png)
+		# N.B. regarding #807364: CMAKE_DISABLE_FIND_PACKAGE_SDL is used only
+		# with USE="allegro -sdl" combination flags. There no other way to
+		# completely disable SDL1 support.
+		-DCMAKE_DISABLE_FIND_PACKAGE_SDL=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_SDL2=$(usex !sdl)
+		-DCMAKE_DISABLE_FIND_PACKAGE_SSE=$(usex !cpu_flags_x86_sse)
+		-DCMAKE_DISABLE_FIND_PACKAGE_ZLIB=$(usex !zlib)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	newinitd "${FILESDIR}"/${PN}.initd-r1 ${PN}
+}
+
+pkg_postinst() {
+	if ! use openmedia ; then
+		elog
+		elog "OpenTTD was compiled without the 'openmedia' USE flag."
+		elog
+		elog "In order to play, you must at least install"
+		elog "games-misc/opengfx, and games-misc/opensfx, or copy the "
+		elog "following 6 files from a version of Transport Tycoon Deluxe"
+		elog "(Windows or DOS) to shared or personal location."
+		elog "See /usr/share/doc/${PF}/directory_structure.md for more info."
+		elog
+		elog "From the Windows version you need: "
+		elog "sample.cat trg1r.grf trgcr.grf trghr.grf trgir.grf trgtr.grf"
+		elog "OR from the DOS version you need: "
+		elog "SAMPLE.CAT TRG1.GRF TRGC.GRF TRGH.GRF TRGI.GRF TRGT.GRF"
+	fi
+}