gnome-base/gnome-keyring: bump to 3.28.2

Bug: https://bugs.gentoo.org/658646
Package-Manager: Portage-2.3.49, Repoman-2.3.10

2 files changed, 80 insertions, 0 deletions

diff --git a/gnome-base/gnome-keyring/Manifest b/gnome-base/gnome-keyring/Manifest
index 53c6f415055a..a7682528e16a 100644
--- a/gnome-base/gnome-keyring/Manifest
+++ b/gnome-base/gnome-keyring/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-keyring-3.20.0.tar.xz 1215324 BLAKE2B 97a4663fac7d3e854a742ac2f160fda2b40c5ff9f7316b52197955aa1970732ef323252325a021469d4944e962b1f1b868d300476b854f21cc5636961e3972da SHA512 f7e6195b4be52edaee3bc3181f006ec31ebd54f8000c98220520f4158f66580b60950e4f55247aefae6aa9320f6589c8a09c1e32853165915ae5ff1b40627c5b
 DIST gnome-keyring-3.20.1.tar.xz 1219800 BLAKE2B b0c633575ee35a733bbf04322e4413675bc40d4de256b66183138483f50c1d399a450cd4d06a3d76707948a7c541ef129a3385044f109a37677af6a7fc01e9af SHA512 a60d8a4b17a9c6d8c581578881abaf7d79de43045a314b401e3bfd3974edb4ab94117dd430203b721058f432b24bf6296e0b7c4fba1e66cccd2c2e9441787177
+DIST gnome-keyring-3.28.2.tar.xz 1322108 BLAKE2B 416697befb7670c3b854ff8d70626d495f5ba77691a062f854360e25a76766f5023e998b86114d36965023a5efefc2eb0ab1dca9aa03d73351eafebaa4920784 SHA512 a51bc9d6bc9203b86febe99bdbf893d3ba0eeaad976ece2bd49efc3869bd1d15f440a01999ce969f845f8336538de22e9f1161da990d707cbadb99d5cc3549bc
diff --git a/gnome-base/gnome-keyring/gnome-keyring-3.28.2.ebuild b/gnome-base/gnome-keyring/gnome-keyring-3.28.2.ebuild
new file mode 100644
index 000000000000..9c67aff73b7d
--- /dev/null
+++ b/gnome-base/gnome-keyring/gnome-keyring-3.28.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit fcaps gnome2 pam python-any-r1 versionator virtualx
+
+DESCRIPTION="Password and keyring managing daemon"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+caps pam selinux +ssh-agent test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+# Replace gkd gpg-agent with pinentry[gnome-keyring] one, bug #547456
+RDEPEND="
+	>=app-crypt/gcr-3.27.90:=[gtk]
+	>=dev-libs/glib-2.44:2
+	app-misc/ca-certificates
+	>=dev-libs/libgcrypt-1.2.2:0=
+	caps? ( sys-libs/libcap-ng )
+	pam? ( virtual/pam )
+	selinux? ( sec-policy/selinux-gnome )
+	>=app-crypt/gnupg-2.0.28:=
+	net-misc/openssh
+"
+DEPEND="${RDEPEND}
+	>=app-eselect/eselect-pinentry-0.5
+	app-text/docbook-xml-dtd:4.3
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.9.18
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+PDEPEND="app-crypt/pinentry[gnome-keyring]" #570512
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Disable stupid CFLAGS with debug enabled
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-ssh-agent \
+		$(use_with caps libcap-ng) \
+		$(use_enable pam) \
+		$(use_with pam pam-dir $(getpam_mod_dir)) \
+		$(use_enable selinux) \
+		$(use_enable ssh-agent) \
+		--enable-doc
+}
+
+src_test() {
+	 "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/schema" || die
+	 GSETTINGS_SCHEMA_DIR="${S}/schema" virtx emake check
+}
+
+pkg_postinst() {
+	# cap_ipc_lock only needed if building --with-libcap-ng
+	# Never install as suid root, this breaks dbus activation, see bug #513870
+	use caps && fcaps -m 755 cap_ipc_lock usr/bin/gnome-keyring-daemon
+	gnome2_pkg_postinst
+
+	if ! [[ $(eselect pinentry show | grep "pinentry-gnome3") ]] ; then
+		ewarn "Please select pinentry-gnome3 as default pinentry provider:"
+		ewarn " # eselect pinentry set pinentry-gnome3"
+	fi
+}