gnome-extra/gnome-contacts: bump to 3.30.2, ebuild touchups

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index 8ebe1bec54db..76e4e03079e3 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1,3 +1,4 @@
 DIST gnome-contacts-3.22.1.tar.xz 788820 BLAKE2B 8f620334dd380e8cb690f7b71d3a99a921f5814ab230690a60be6022150db7a6a0f74e426e72d8d027eb5280e1b6bfd04fa7b0b030519bb19e4718ca0c9f2120 SHA512 d93ed6c65ffdabe1925cc795b88ff374fe69e03fcd36af7c2fc67a5236b90ab6af4bd269b6fc3b344fcd6b4688d866628b8b090bb62de95f8bd0c2e40c26a107
 DIST gnome-contacts-3.26.1.tar.xz 974588 BLAKE2B da989125408702099ecd1afaad6c06ab1cbeda2309bc7b207be671c833792a325bbbba0ebc6561f960d2c524ebd51743a60d5b792a0c2b8126318d38a6d801aa SHA512 1ba445efd71dbc77213d75011b0abcffcf6fe534cba14cf8ca92890e8dfb7b44d9565399200aa7aa03862cf08be60289b78501a1807a760bb1e68f0fe46c4685
 DIST gnome-contacts-3.30.1.tar.xz 369392 BLAKE2B ba3e9263b1de210efec88d2ccecaaf7ae7a6761a5997e213d1a0d9a7694fed54f8123b792e138ec8ac67843408562e320a5490c5daf51478b763b9fbcb21adda SHA512 4aa5629299233d24c36ec1c67d412fc421d5b6836c9759a0278bebe0239897ec6046e3aa8ea7ef10c5e537ec9aed67346221a353f683e18032a708eb333826d7
+DIST gnome-contacts-3.30.2.tar.xz 368476 BLAKE2B 502170e327eb63a6d026af94a09949f6b973dba0c59079a23c7f37dfde2a391ffa13d905452741c403ada8e6f1101f7a5620ad9b59eb4c5341e96d357d8fe99b SHA512 cf6ab33ef6147bceb5a4681b83830828fd4caa47d83fa9f71e01db3caf710f7f09fe60d2956565a2b9bd124356e100b31d6372ac4d4d231718230915a135e79d
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.30.2.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.30.2.ebuild
new file mode 100644
index 000000000000..69d2acc4a714
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.30.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="telepathy v4l"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	net-libs/gnome-online-accounts[vala]
+	gnome-extra/evolution-data-server[vala]
+	net-libs/telepathy-glib[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	>=dev-libs/folks-0.11.4:=[eds,telepathy?]
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-base/gnome-desktop-3.0:3=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.22:3
+	v4l? ( >=media-video/cheese-3.5.91:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.22 )
+"
+DEPEND="${RDEPEND}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use v4l cheese)
+		$(meson_use telepathy)
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}