gnome-extra/gnome-contacts: Version bump

Package-Manager: portage-2.3.0_rc1

2 files changed, 69 insertions, 0 deletions

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index 09412d42a2f7..6c67f02d5683 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1 +1,2 @@
 DIST gnome-contacts-3.18.1.tar.xz 785260 SHA256 0418d25e70e73c05f4db58ce843819ef91180a21531549a832eafeaf2700cf26 SHA512 eda2698215d0a11018fba7742c5038f6a7c34632b5efe05597dddf0a91489139dd9a6b61c9972756d9beabacf1bd8f776feb2e4bd4104512e7809357dbda7d03 WHIRLPOOL a959aed54e3edd7ca033cbdff4a723d2024d7f69d7807bbd2a972f05e5fefaeafe617cc3a1ce4b3552c2dd192f2dc6764872edb8fdcbd04e93029b356fc03ac7
+DIST gnome-contacts-3.20.0.tar.xz 856724 SHA256 bef88dc728aa7bb058c530fd936b262d96bbc17e73d640279842371bb3ad1588 SHA512 aab750bb116ab54fe22518fc2eefce4da2956b55835a0be51b03a8ba2c7e93b4e38f8bfd8c2db961f953141c1d9febb40ab431c0b0049d85a325295a1216ce59 WHIRLPOOL 9f00cc8bdabdf7e832323af2ec6829bde05e45f8de7f16a0d04ef15da3acd38ed2a35891f7f7159680e9fe1c6d937710c14a3dbd24bf909e5e77ceafee7fb809
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.20.0.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.20.0.ebuild
new file mode 100644
index 000000000000..504c412661e6
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.20.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+VALA_MIN_API_VERSION="0.24"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="v4l"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-0.9.6:=
+	dev-libs/folks[vala(+)]
+	gnome-base/gnome-desktop:3=[introspection]
+	gnome-extra/evolution-data-server[vala]
+	net-libs/telepathy-glib[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=dev-libs/folks-0.9.5:=[eds,telepathy]
+	>=dev-libs/glib-2.37.6:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	>=gnome-base/gnome-desktop-3.0:3=
+	media-libs/clutter:1.0
+	media-libs/clutter-gtk:1.0
+	media-libs/libchamplain:0.12
+	net-libs/gnome-online-accounts:=
+	>=net-libs/telepathy-glib-0.17.5
+	>=sci-geosciences/geocode-glib-3.15.3
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.20.0:3
+	x11-libs/pango
+	v4l? ( >=media-video/cheese-3.5.91:= )
+"
+DEPEND="${RDEPEND}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Regenerate the pre-generated C sources, bug #471628
+	if ! use v4l; then
+		touch src/*.vala
+	fi
+
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure $(use_with v4l cheese)
+}