gnome-extra/gnome-contacts: bump to 3.36.2

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index 47eda3c9d99e..c9c5caf85477 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-contacts-3.30.2.tar.xz 368476 BLAKE2B 502170e327eb63a6d026af94a09949f6b973dba0c59079a23c7f37dfde2a391ffa13d905452741c403ada8e6f1101f7a5620ad9b59eb4c5341e96d357d8fe99b SHA512 cf6ab33ef6147bceb5a4681b83830828fd4caa47d83fa9f71e01db3caf710f7f09fe60d2956565a2b9bd124356e100b31d6372ac4d4d231718230915a135e79d
 DIST gnome-contacts-3.34.1.tar.xz 365384 BLAKE2B 3563ce0784c19b2cf61e3cad60afaeaa310c53c68f11da459a3053df6be769fe0bdfea84f106e11fd2921c3f6bf8ef6a03b8cd90a680dc5b46d9a0486fd0c737 SHA512 6dad3fd9d199ad87c642e9f36102a142958cd3f577eba36fa3ed2800af5acb44752fa1f8b7eb8991974c514245af51015e6b5e08636274b9048813c37abcc478
+DIST gnome-contacts-3.36.2.tar.xz 635932 BLAKE2B 9bcdf093d99477d1162c9ea78007e65cf20a1e4038fe284fafa4c174ab1d1d0c2ceb7ec2806c9abeed1c8ab168549c80b2763e65ece22c76a9044781eef8ed5d SHA512 ebbce67aa5c0af55559230c558c5f28b065182d434582431595bffedc25dd0ec3caa44e60f4670b4b2a1f784e90c8dd4f56df937054697b4ea932a39da78f1c1
diff --git a/gnome-extra/gnome-contacts/gnome-contacts-3.36.2.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-3.36.2.ebuild
new file mode 100644
index 000000000000..f60c41444e55
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-3.36.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="telepathy v4l"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	net-libs/gnome-online-accounts[vala]
+	gnome-extra/evolution-data-server[gtk,vala]
+	telepathy? ( net-libs/telepathy-glib[vala] )
+	gui-libs/libhandy:0.0[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
+	>=dev-libs/folks-0.11.4:=[eds,telepathy?]
+	>=dev-libs/glib-2.44:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-base/gnome-desktop-3.0:3=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.23.1:3
+	v4l? ( >=media-video/cheese-3.5.91:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.22 )
+	>=gui-libs/libhandy-0.0.12:0.0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use v4l cheese)
+		$(meson_use telepathy)
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}