gnome-extra/gnome-shell-extension-gsconnect: add 58

Upstream broke the test run completely:
https://github.com/GSConnect/gnome-shell-extension-gsconnect/issues/1786

Closes: https://bugs.gentoo.org/925536
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-gsconnect/Manifest b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
index 2a10857cf486..1d89f38ca981 100644
--- a/gnome-extra/gnome-shell-extension-gsconnect/Manifest
+++ b/gnome-extra/gnome-shell-extension-gsconnect/Manifest
@@ -1 +1,2 @@
 DIST gnome-shell-extension-gsconnect-56.tar.gz 876272 BLAKE2B a389ad50585bed2826f6a4b12552c5d6ff431bf4674d23710c992eb4a89cd3ecc363cddb90a2e14c65f14061a4be1c43ab956e3646b814de454d32ef08e9cf91 SHA512 3db4703f6cef3a389b4a05867725fc1c29fa18b38fd0696922c8110b3efa181dee892ebc89586538d8425de81ce3d81e6541eae685601dbdc6c8b160c1826e47
+DIST gnome-shell-extension-gsconnect-58.tar.gz 899868 BLAKE2B c39e6d82792b9e612d68fc98460b801b51ed8087a94d8eee949ff99a15f058d08842e4b4a3f22050c61ee0d71f1e58aa2574efd9fe685e267afb90492793bce1 SHA512 bc69455271afd51ccb861c66edd21b37bac449e003c560707ab30e2e062ca89f9caa60d697543d81c1c387b54a1f34912be522067b14b953a79a2e089a2612f4
diff --git a/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-58.ebuild b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-58.ebuild
new file mode 100644
index 000000000000..2b8ff9879e7b
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-58.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2-utils meson readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="KDE Connect implementation for Gnome Shell"
+HOMEPAGE="https://github.com/GSConnect/gnome-shell-extension-gsconnect"
+SRC_URI="https://github.com/GSConnect/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="nautilus"
+
+# Upstream broke them and now they need to be run after pkg is installed or
+# a container needs to be used:
+# https://github.com/GSConnect/gnome-shell-extension-gsconnect/issues/1786
+RESTRICT="test"
+
+COMMON_DEPEND="dev-libs/glib:2"
+RDEPEND="${COMMON_DEPEND}
+	app-eselect/eselect-gnome-shell-extensions
+	>=dev-libs/gjs-1.68
+	>=gnome-base/gnome-shell-46
+	gnome-base/gvfs
+	gnome-extra/evolution-data-server
+	|| ( media-libs/libcanberra media-libs/gsound )
+	nautilus? (
+		dev-python/nautilus-python
+		gnome-base/nautilus[introspection] )
+"
+DEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="For knowing more about how to do the setup, please visit:
+https://github.com/GSConnect/gnome-shell-extension-gsconnect/wiki/Installation"
+
+src_configure() {
+	# nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
+	# https://bugs.gentoo.org/694388
+	meson_src_configure \
+		-Dinstalled_tests=false \
+		-Dnemo=false \
+		$(meson_use nautilus)
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	gnome2_schemas_savelist
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}