gui-apps/waybar: add 0.10.4

- remove double libinput RDEPEND
- add pipewire to RDEPEND with subslot operator
- add wayland-scanner to BDEPEND
- add upower subslot binder to trigger rebuilds
- removed libevdev subslot operator as there are no slots
- sorted RDEPEND

Signed-off-by: Filip Kobierski <fkobi@pm.me>
Closes: https://github.com/gentoo/gentoo/pull/37743
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/gui-apps/waybar/Manifest b/gui-apps/waybar/Manifest
index 04a7a9c5db4d..eaff843439a4 100644
--- a/gui-apps/waybar/Manifest
+++ b/gui-apps/waybar/Manifest
@@ -1 +1,2 @@
 DIST waybar-0.10.3.tar.gz 301886 BLAKE2B 0ef1cf82cc9f374c756724c389a045d2d9e26a5403eeb527ab0885d89d6030bea74aa5c299f8f865c244524c485a90ad3fee071968d21ff728c1f46f75f637b4 SHA512 2e90007056b79bccad06902db2e8b6f25103bb7c86736cb0b7dc260795bc4a1b5db7a7b8a4bebe9169f0590585fd6b170193cf8aa5437d69bab0f78d66922084
+DIST waybar-0.10.4.tar.gz 309411 BLAKE2B 907273e6f1371252aad05212b4c59eabe1662167659d22073ee3bf649d8ee43be852b996dd7b86eecd0384b833cd2d7b9eed69b6b3292cb0b9cdbeb88c9e2391 SHA512 e6b25e242c67cae6566c5db9f4cba55ec4fb57cd7345ca3f5d24126ecf5bde150fb8d5cd14f80d3462f81254e1789986c28e3ebdb4227e8c5c8ddcf10fcfd49c
diff --git a/gui-apps/waybar/waybar-0.10.4.ebuild b/gui-apps/waybar/waybar-0.10.4.ebuild
new file mode 100644
index 000000000000..cd49640ad2a5
--- /dev/null
+++ b/gui-apps/waybar/waybar-0.10.4.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors"
+HOMEPAGE="https://github.com/Alexays/Waybar"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
+else
+	SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+	S="${WORKDIR}/${PN^}-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="evdev experimental jack +libinput +logind mpd mpris network pipewire pulseaudio sndio systemd test tray +udev upower wifi"
+REQUIRED_USE="
+	upower? ( logind )
+"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=app-text/scdoc-1.9.2
+	dev-util/gdbus-codegen
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-cpp/cairomm:0
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-libs/glib:2
+	dev-libs/jsoncpp:=
+	dev-libs/libsigc++:2
+	>=dev-libs/libfmt-8.1.1:=
+	>=dev-libs/spdlog-1.10.0:=
+	dev-libs/date:=
+	dev-libs/wayland
+	gui-libs/gtk-layer-shell
+	gui-libs/wlroots:=
+	media-video/pipewire:=
+	x11-libs/gtk+:3[wayland]
+	x11-libs/libxkbcommon
+	evdev? ( dev-libs/libevdev )
+	jack? ( virtual/jack )
+	libinput? ( dev-libs/libinput:= )
+	logind? (
+		|| ( sys-apps/systemd
+			 sys-auth/elogind )
+	)
+	mpd? ( media-libs/libmpdclient )
+	mpris? ( >=media-sound/playerctl-2 )
+	network? ( dev-libs/libnl:3 )
+	pipewire? ( media-video/wireplumber:0/0.5 )
+	pulseaudio? ( media-libs/libpulse )
+	sndio? ( media-sound/sndio:= )
+	systemd? ( sys-apps/systemd:= )
+	tray? (
+		dev-libs/libayatana-appindicator
+		dev-libs/libdbusmenu[gtk3]
+	)
+	udev? ( virtual/libudev:= )
+	upower? ( sys-power/upower:= )
+	wifi? ( sys-apps/util-linux )
+"
+DEPEND="${RDEPEND}
+	dev-libs/wayland-protocols
+	test? ( dev-cpp/catch:0 )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		-Dcava=disabled
+		$(meson_feature evdev libevdev)
+		$(meson_feature jack)
+		$(meson_feature libinput)
+		$(meson_feature logind)
+		$(meson_feature mpd)
+		$(meson_feature mpris)
+		$(meson_feature network libnl)
+		$(meson_feature pulseaudio)
+		$(meson_feature pipewire wireplumber)
+		$(meson_feature pipewire)
+		$(meson_feature sndio)
+		$(meson_feature systemd)
+		$(meson_feature test tests)
+		$(meson_feature tray dbusmenu-gtk)
+		$(meson_feature udev libudev)
+		$(meson_feature upower upower_glib)
+		$(meson_feature wifi rfkill)
+		$(meson_use experimental)
+	)
+	meson_src_configure
+}