gui-libs/wlroots: drop versions revert

This reverts commit 5767143d5a5537baa0aafa30bf7847f655b85131.

Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/gui-libs/wlroots/wlroots-0.14.1-r1.ebuild b/gui-libs/wlroots/wlroots-0.14.1-r1.ebuild
new file mode 100644
index 000000000000..da27838ebd01
--- /dev/null
+++ b/gui-libs/wlroots/wlroots-0.14.1-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://github.com/swaywm/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+	inherit git-r3
+	SLOT="0/9999"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+	SLOT="0/14"
+fi
+
+LICENSE="MIT"
+IUSE="x11-backend X"
+
+DEPEND="
+	>=dev-libs/libinput-1.14.0:0=
+	>=dev-libs/wayland-1.19.0
+	>=dev-libs/wayland-protocols-1.17.0
+	media-libs/mesa[egl(+),gles2,gbm(+)]
+	sys-auth/seatd:=
+	virtual/libudev
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.17
+	>=dev-util/meson-0.56.0
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		"-Dexamples=false"
+		"-Drenderers=gles2"
+		-Dxwayland=$(usex X enabled disabled)
+		-Dx11-backend=$(usex x11-backend enabled disabled)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}