kde-apps: Add KDE Applications 17.12.3

Package-Manager: Portage-2.3.19, Repoman-2.3.6

2 files changed, 122 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index f271710e1f2f..2ec4cc3ae907 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-17.08.3.tar.xz 10565760 BLAKE2B 75d98ab39ff4691baadc1c8a26f635981d7bb086c154a7c4e06dda79d4756f781c76b126838d3b0ea141f98750df09dd16a5dd9978340eedd1dc3a7acff45ed3 SHA512 91038cc862bdebad1cfa843e8688a71494140cdf59fc8f9815a6e6eef2dca40b94ee7d0a8e7c6b277004ff0945431bb7873113e6e7fc5649b8120ef03b1564ba
 DIST k3b-17.12.2.tar.xz 10574600 BLAKE2B 9eed0034872b3509510cfa78e7f3e8fe2bfbed0004568e2c80a18972d02c255b1f5e287202e7fabbd24a6f0e43f60042b19042485e75b1c40a42d88b49a587ee SHA512 2e1de62fab8e1e702b9a7c3431e44c2809376a329ba9236e056336d26c885b37e956059375d5f26f1b5c94093ccca80524d497a4b0328f277204293461b249de
+DIST k3b-17.12.3.tar.xz 10573616 BLAKE2B e5606f7ef96aa34cf2aba068cd7417bd1783910f759dffa2bb4edab3d2e921788513b22839c8e6156f304db4e81b3a6889d1bdf7b4648f64e2cbd383fe032705 SHA512 05cd1413d99f55c4aca5b75cd51691fa0ca0a975660168ee3effa39774deab36d28ef3e7c71860c726d1e7e02b3ac12e6372e2e47bb64d5fa5e21f58540d11e1
diff --git a/kde-apps/k3b/k3b-17.12.3.ebuild b/kde-apps/k3b/k3b-17.12.3.ebuild
new file mode 100644
index 000000000000..33ccd3437be8
--- /dev/null
+++ b/kde-apps/k3b/k3b-17.12.3.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+KEYWORDS="~amd64 ~x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kfilemetadata 'taglib?')
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webkit? ( $(add_qt_dep qtwebkit) )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}