kde-plasma/plasma-meta: 5.21.5 version bump

See also: https://kde.org/announcements/plasma/5/5.21.5/

Bug: https://bugs.gentoo.org/788820
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 108 insertions, 0 deletions

diff --git a/kde-plasma/plasma-meta/metadata.xml b/kde-plasma/plasma-meta/metadata.xml
index 0f90ac488608..2681c26c0ebe 100644
--- a/kde-plasma/plasma-meta/metadata.xml
+++ b/kde-plasma/plasma-meta/metadata.xml
@@ -8,6 +8,7 @@
 	<use>
 		<flag name="browser-integration">Enable integration with Chrome/Firefox with browser extensions</flag>
 		<flag name="colord">Enable <pkg>kde-plasma/kwin</pkg> color management via <pkg>x11-misc/colord</pkg></flag>
+		<flag name="crash-handler">Pull in <pkg>kde-plasma/drkonqi</pkg> for assisted upstream crash reports</flag>
 		<flag name="crypt">Pull in <pkg>kde-plasma/plasma-vault</pkg> for encrypted vaults integration</flag>
 		<flag name="desktop-portal">Enable <pkg>sys-apps/xdg-desktop-portal</pkg> backend implementation for Plasma</flag>
 		<flag name="discover">Pull in resources management GUI; a centralised GHNS alternative and optional <pkg>sys-apps/fwupd</pkg> frontend</flag>
diff --git a/kde-plasma/plasma-meta/plasma-meta-5.21.5.ebuild b/kde-plasma/plasma-meta/plasma-meta-5.21.5.ebuild
new file mode 100644
index 000000000000..240dc1de7b29
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-5.21.5.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Merge this to pull in all Plasma 5 packages"
+HOMEPAGE="https://kde.org/plasma-desktop/"
+
+LICENSE="metapackage"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="accessibility bluetooth +browser-integration colord +crash-handler crypt
++desktop-portal discover +display-manager +elogind +firewall grub gtk +handbook
++kwallet +legacy-systray +networkmanager plymouth pulseaudio qrcode +sddm sdk
++smart systemd thunderbolt +wallpapers"
+
+REQUIRED_USE="^^ ( elogind systemd )"
+
+RDEPEND="
+	>=kde-plasma/breeze-${PV}:${SLOT}
+	>=kde-plasma/kactivitymanagerd-${PV}:${SLOT}
+	>=kde-plasma/kde-cli-tools-${PV}:${SLOT}
+	>=kde-plasma/kdecoration-${PV}:${SLOT}
+	>=kde-plasma/kdeplasma-addons-${PV}:${SLOT}
+	>=kde-plasma/kgamma-${PV}:${SLOT}
+	>=kde-plasma/khotkeys-${PV}:${SLOT}
+	>=kde-plasma/kinfocenter-${PV}:${SLOT}
+	>=kde-plasma/kmenuedit-${PV}:${SLOT}
+	>=kde-plasma/kscreen-${PV}:${SLOT}
+	>=kde-plasma/kscreenlocker-${PV}:${SLOT}
+	>=kde-plasma/ksshaskpass-${PV}:${SLOT}
+	>=kde-plasma/ksysguard-${PV}:${SLOT}
+	>=kde-plasma/kwayland-integration-${PV}:${SLOT}
+	>=kde-plasma/kwayland-server-${PV}:${SLOT}
+	>=kde-plasma/kwin-${PV}:${SLOT}
+	>=kde-plasma/kwrited-${PV}:${SLOT}
+	>=kde-plasma/libkscreen-${PV}:${SLOT}
+	>=kde-plasma/libksysguard-${PV}:${SLOT}
+	>=kde-plasma/milou-${PV}:${SLOT}
+	>=kde-plasma/oxygen-${PV}:${SLOT}
+	>=kde-plasma/plasma-desktop-${PV}:${SLOT}
+	>=kde-plasma/plasma-integration-${PV}:${SLOT}
+	>=kde-plasma/plasma-systemmonitor-${PV}:${SLOT}
+	>=kde-plasma/plasma-workspace-${PV}:${SLOT}
+	>=kde-plasma/polkit-kde-agent-${PV}:${SLOT}
+	>=kde-plasma/powerdevil-${PV}:${SLOT}
+	>=kde-plasma/systemsettings-${PV}:${SLOT}
+	sys-apps/dbus[elogind?,systemd?]
+	sys-auth/polkit[elogind?,systemd?]
+	sys-fs/udisks:2[elogind?,systemd?]
+	bluetooth? ( >=kde-plasma/bluedevil-${PV}:${SLOT} )
+	browser-integration? ( >=kde-plasma/plasma-browser-integration-${PV}:${SLOT} )
+	colord? ( x11-misc/colord )
+	crash-handler? ( >=kde-plasma/drkonqi-${PV}:${SLOT} )
+	crypt? ( >=kde-plasma/plasma-vault-${PV}:${SLOT} )
+	desktop-portal? ( >=kde-plasma/xdg-desktop-portal-kde-${PV}:${SLOT} )
+	discover? ( >=kde-plasma/discover-${PV}:${SLOT} )
+	display-manager? (
+		sddm? (
+			>=kde-plasma/sddm-kcm-${PV}:${SLOT}
+			x11-misc/sddm[elogind?,systemd?]
+		)
+		!sddm? ( x11-misc/lightdm )
+	)
+	elogind? ( sys-auth/elogind[pam] )
+	grub? ( >=kde-plasma/breeze-grub-${PV}:${SLOT} )
+	gtk? (
+		>=kde-plasma/breeze-gtk-${PV}:${SLOT}
+		>=kde-plasma/kde-gtk-config-${PV}:${SLOT}
+		x11-misc/appmenu-gtk-module
+	)
+	handbook? ( kde-apps/khelpcenter:5 )
+	kwallet? ( >=kde-plasma/kwallet-pam-${PV}:${SLOT} )
+	legacy-systray? ( >=kde-plasma/xembed-sni-proxy-${PV}:${SLOT} )
+	networkmanager? (
+		>=kde-plasma/plasma-nm-${PV}:${SLOT}
+		net-misc/networkmanager[elogind?,systemd?]
+		qrcode? ( kde-frameworks/prison[qml] )
+	)
+	plymouth? (
+		>=kde-plasma/breeze-plymouth-${PV}:${SLOT}
+		>=kde-plasma/plymouth-kcm-${PV}:${SLOT}
+	)
+	pulseaudio? ( >=kde-plasma/plasma-pa-${PV}:${SLOT} )
+	sdk? ( >=kde-plasma/plasma-sdk-${PV}:${SLOT} )
+	smart? ( >=kde-plasma/plasma-disks-${PV}:${SLOT} )
+	systemd? (
+		sys-apps/systemd[pam]
+		firewall? ( >=kde-plasma/plasma-firewall-${PV}:${SLOT} )
+	)
+	thunderbolt? ( >=kde-plasma/plasma-thunderbolt-${PV}:${SLOT} )
+	wallpapers? ( >=kde-plasma/plasma-workspace-wallpapers-${PV}:${SLOT} )
+"
+# Optional runtime deps: kde-plasma/plasma-desktop
+RDEPEND="${RDEPEND}
+	accessibility? ( app-accessibility/orca )
+"
+
+pkg_postinst() {
+	has_version sys-auth/consolekit || return
+	ewarn "An existing installation of sys-auth/consolekit was detected even though"
+	ewarn "${PN} was configured with USE $(usex elogind elogind systemd)."
+	ewarn "There can only be one session manager at runtime, otherwise random issues"
+	ewarn "may occur. Please make sure USE consolekit is nowhere enabled in make.conf"
+	ewarn "or package.use and remove sys-auth/consolekit before raising bugs."
+	ewarn "For more information, visit https://wiki.gentoo.org/wiki/KDE"
+}