media-gfx/imv: add 4.4.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/media-gfx/imv/Manifest b/media-gfx/imv/Manifest
index 8fccc1554af9..b3bb76e4d202 100644
--- a/media-gfx/imv/Manifest
+++ b/media-gfx/imv/Manifest
@@ -1 +1,2 @@
 DIST imv-4.3.1_p20211221.tar.gz 80082 BLAKE2B 2b4f3cdb0b7123b978cdbc588cf686c38d65053e3fadb6532da45be3e24b35a297639ca8ddb7d05945f92763cc014a232eb0ca0af0da059b2dac48d2b3c9939d SHA512 7579930a406d2ba1dca7f043d635ea89301606d06ca5ebe5779fffd1410789bb07ef8228beb2ef08af2783e64deda8b67aa991fc56333c0e60051f7666fbb19f
+DIST imv-4.4.0.tar.gz 80360 BLAKE2B c598bb270ed57562f1c1b9a56f42676a7c8390c976ed74405228da572b000a85bf69e51f1bbfa6d554a481debc092995fe5222ba1e8b0b029b72395a8b8f329b SHA512 ddc0740022183a5467a0815ca623d2204b26449fee14b00c3468d06dbba3b5c3314b04a582bbac6075205f8d58cc24f157e283ce1ce3d34ecf0a9bdc497ab7f1
diff --git a/media-gfx/imv/imv-4.4.0.ebuild b/media-gfx/imv/imv-4.4.0.ebuild
new file mode 100644
index 000000000000..2aca12fa827d
--- /dev/null
+++ b/media-gfx/imv/imv-4.4.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~exec64/imv/"
+else
+	SRC_URI="https://git.sr.ht/~exec64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://sr.ht/~exec64/imv/"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+IUSE="+X +freeimage gif heif icu jpeg png svg test tiff wayland"
+REQUIRED_USE="|| ( X wayland )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/cairo
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb:=
+	)
+	freeimage? ( media-libs/freeimage )
+	gif? ( media-libs/libnsgif )
+	heif? ( media-libs/libheif:= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( >=dev-libs/libgrapheme-2:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
+	svg? ( >=gnome-base/librsvg-2.44:2 )
+	tiff? ( media-libs/tiff:= )
+	wayland? ( dev-libs/wayland )
+	!sys-apps/renameutils"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( dev-util/cmocka )"
+BDEPEND="
+	app-text/asciidoc
+	wayland? ( dev-util/wayland-scanner )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.3.1_p20211221-animated-gif.patch
+)
+
+src_prepare() {
+	default
+
+	# if wayland-only, don't automagic on libGL and force libOpenGL
+	if ! use X; then
+		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
+	fi
+
+	# glu isn't used by anything
+	sed -i "/dependency('glu')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature freeimage)
+		$(meson_feature gif libnsgif)
+		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature png libpng)
+		$(meson_feature svg librsvg)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
+		-Dunicode=$(usex icu{,} grapheme)
+		-Dwindows=$(usex X $(usex wayland all x11) wayland)
+	)
+
+	meson_src_configure
+}