media-gfx/mandelbulber: Bump to version 2.26

* EAPI=8,
* IUSE+=joystick (needs dev-qt/qtgamepad),
* add missing dependency on opencl? (dev-libs/clhpp ),
* add github SRC_URI.

Some changes taken from the patch by Samuel Bauer in bug #722890.

Closes: https://bugs.gentoo.org/688410
Closes: https://bugs.gentoo.org/722890
Signed-off-by: Alexander Miller <alex.miller@gmx.de>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/media-gfx/mandelbulber/Manifest b/media-gfx/mandelbulber/Manifest
index eca3ca3f3ade..5814dad8fe2d 100644
--- a/media-gfx/mandelbulber/Manifest
+++ b/media-gfx/mandelbulber/Manifest
@@ -1 +1,2 @@
 DIST mandelbulber2-2.12-1.tar.gz 47092910 BLAKE2B 1e5ca64a4819052882bc7cdc047c6d755046f2ceebcf7b26db41511fde219aa523a3c6884f0667aed1365104c4502a6e6b1b2d7d40a4a024fdb5051d5ac13cd2 SHA512 5dc8dcaa45bc8747024ed16379cc4d622535099c925abf3c2aa01c0338fe8c1f272e6113b6bf28da6a4bb087e6d6e6a4c6634feca993d2c89f12b79582ff271c
+DIST mandelbulber2-2.26.tar.gz 113563064 BLAKE2B 6fd333a42f5e4b106b950079277ff1bb6cc2395382e12ea37424df137ed11cf5fb103185b325d9615bd890404fe596133644a5cdd3911140eabb2f8c0c1d0e14 SHA512 cc547cab6e2b672a35be5d3d214ad3b292eaf1b3b06daf12cecce0f69e612fcfb4123cd837fd87003eea3103086947639fd04cae4b0ed7cd231d78e5d775e299
diff --git a/media-gfx/mandelbulber/mandelbulber-2.26.ebuild b/media-gfx/mandelbulber/mandelbulber-2.26.ebuild
new file mode 100644
index 000000000000..2a64d2e17401
--- /dev/null
+++ b/media-gfx/mandelbulber/mandelbulber-2.26.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${PN}2-${PV}"
+inherit desktop qmake-utils xdg-utils
+
+DESCRIPTION="Tool to render 3D fractals"
+HOMEPAGE="https://www.mandelbulber.com"
+SRC_URI="https://github.com/buddhi1980/${PN}2/releases/download/${PV}/${MY_P}.tar.gz mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="CC-BY-4.0 GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="joystick opencl openexr sndfile tiff"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-libs/lzo
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	media-libs/libpng:0=
+	sci-libs/gsl:=
+	joystick? ( dev-qt/qtgamepad:5 )
+	opencl? (
+		dev-libs/clhpp
+		virtual/opencl
+	)
+	openexr? (
+		media-libs/ilmbase:=
+		media-libs/openexr:=
+	)
+	sndfile? ( media-libs/libsndfile )
+	tiff? ( media-libs/tiff:0 )
+"
+DEPEND="${RDEPEND}
+	dev-qt/designer:5
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+
+	use joystick || sed -i -e "s/qtHaveModule(gamepad)/false/" makefiles/common.pri || die
+	use openexr || sed -i -e "s/packagesExist(IlmBase)/false/" makefiles/common.pri || die
+	use sndfile || sed -i -e "s/packagesExist(sndfile)/false/" makefiles/common.pri || die
+	use tiff || sed -i -e "s/packagesExist(libtiff-4)/false/" makefiles/common.pri || die
+}
+
+src_configure() {
+	if use opencl; then
+		eqmake5 makefiles/${PN}-opencl.pro
+	else
+		eqmake5 makefiles/${PN}.pro
+	fi
+}
+
+src_install() {
+	dobin ${PN}2
+
+	dodoc README NEWS usr/share/doc/${PN}2/Mandelbulber_Manual.pdf
+
+	insinto /usr/share/${PN}2
+	doins -r usr/share/${PN}2/*
+
+	insinto /usr/share/applications
+	doins ${PN}2.desktop
+
+	newicon -s 256 qt/icons/${PN}.png ${PN}2.png
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}