media-libs/glycin-loaders: Bump to 1.1.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/media-libs/glycin-loaders/Manifest b/media-libs/glycin-loaders/Manifest
index a3f1c73ef0b2..074c48886188 100644
--- a/media-libs/glycin-loaders/Manifest
+++ b/media-libs/glycin-loaders/Manifest
@@ -1 +1,2 @@
 DIST glycin-1.1.2.tar.xz 28347232 BLAKE2B fca58f99c8f2096a8d339e32a90435f56547f85715b95a5dd5da754c3d47adae712ea6d0bd9b8f7c6678f9b690837da721203a27ddf461cab16130cc7f3c17d2 SHA512 6eef9d21c5f4a423acea41e82b205de3a4dc0e3a5ce235f6cda4b4bd1052703cb9f4e16095b0927ff9185300c32e8631480d73ac313bda9a58c70122a9b7c3e8
+DIST glycin-1.1.4.tar.xz 28352904 BLAKE2B 0623a05462fb8a59d9d7e7f49968b4b68a26bd4f2088702d857048f206e9bc466907dfe2b979fdd4f80ee08e9daa888e4210cc177ca8ca5cc87fc9c10bd86e03 SHA512 8bfeefbbc36794d8b57ac86a0166038372c93aeec65a335db91a098f7442f9d33838c7f657f6a98b5528f62f89cc24b6d52e0e45738e333a3fe0179d0b02ee8c
diff --git a/media-libs/glycin-loaders/glycin-loaders-1.1.4.ebuild b/media-libs/glycin-loaders/glycin-loaders-1.1.4.ebuild
new file mode 100644
index 000000000000..bef17192a368
--- /dev/null
+++ b/media-libs/glycin-loaders/glycin-loaders-1.1.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo meson
+
+MY_P=glycin-${PV/_/.}
+DESCRIPTION="Loaders for glycin clients (glycin crate or libglycin)"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/glycin/"
+SRC_URI="
+	https://download.gnome.org/sources/glycin/$(ver_cut 1-2)/${MY_P}.tar.xz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD GPL-3+ ISC MIT
+	Unicode-DFS-2016
+	|| ( LGPL-2.1+ MPL-2.0 )
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="heif jpegxl svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.60:2
+	>=sys-libs/libseccomp-2.5.0
+	heif? ( >=media-libs/libheif-1.17.0:= )
+	jpegxl? ( >=media-libs/libjxl-0.10.0:= )
+	svg? (
+		>=gnome-base/librsvg-2.52.0:2
+		>=x11-libs/cairo-1.17.0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=gui-libs/gtk-4.12.0:4
+		>=media-libs/lcms-2.14:2
+	)
+"
+BDEPEND="
+	test? (
+		sys-apps/bubblewrap
+		sys-apps/dbus
+	)
+"
+
+ECARGO_VENDOR=${S}/vendor
+
+QA_FLAGS_IGNORED="usr/libexec/glycin-loaders/.*"
+
+src_prepare() {
+	default
+
+	# https://gitlab.gnome.org/GNOME/glycin/-/issues/81
+	sed -i -e '\|/fonts|d' tests/tests.rs || die
+}
+
+src_configure() {
+	local formats=(
+		$(usev heif glycin-heif)
+		$(usev jpegxl glycin-jxl)
+		$(usev svg glycin-svg)
+		glycin-image-rs
+	)
+	local formats_s=${formats[*]}
+	local emesonargs=(
+		-Dprofile=$(usex debug dev release)
+		-Dglycin-loaders=true
+		-Dloaders="${formats_s// /,}"
+		-Dtests=$(usex test true false)
+		-Dlibglycin=false
+	)
+
+	meson_src_configure
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
+
+src_test() {
+	# tests write to /proc/*/uid_map
+	# apparently, "addpredict /" in Portage breaks it
+	local -x SANDBOX_ON=0
+	meson_src_test
+}