media-libs/libpagemaker: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 18 insertions, 14 deletions

diff --git a/media-libs/libpagemaker/libpagemaker-0.0.4.ebuild b/media-libs/libpagemaker/libpagemaker-0.0.4-r1.ebuild
index cd985418d5e9..56a3258992fd 100644
--- a/media-libs/libpagemaker/libpagemaker-0.0.4.ebuild
+++ b/media-libs/libpagemaker/libpagemaker-0.0.4-r1.ebuild
@@ -1,20 +1,20 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
-
-EGIT_REPO_URI="git://gerrit.libreoffice.org/${PN}.git"
-[[ ${PV} == 9999 ]] && inherit autotools git-r3
-
+EAPI=8
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.libreoffice.org/libpagemaker"
+	inherit autotools git-r3
+else
+	SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
+	KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
+fi
 DESCRIPTION="C++ Library that parses the file format of Aldus/Adobe PageMaker documents"
 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libpagemaker"
-[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="amd64 ~arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
 IUSE="debug doc tools"
 
 RDEPEND="
@@ -22,23 +22,27 @@ RDEPEND="
 "
 DEPEND="${RDEPEND}
 	dev-libs/boost
+"
+BDEPEND="
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )
 "
 
 src_prepare() {
 	default
-	[[ ${PV} == 9999 ]] && eautoreconf
+	[[ ${PV} == *9999 ]] && eautoreconf
 }
 
 src_configure() {
-	econf \
-		--disable-werror \
-		$(use_with doc docs) \
+	local myeconfargs=(
+		--disable-werror
+		$(use_with doc docs)
 		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
 	default
-	find "${D}" -name '*.la' -delete || die
+	find "${ED}" -name '*.la' -type f -delete || die
 }