media-libs/libpng: add 1.6.41

Switch to 'libpng-apng' for apng for 1.6.41 as it applies unlike the 'apng' one,
and suffix the distfile name with the repo we got it from to avoid collisions.

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 78 insertions, 6 deletions

diff --git a/media-libs/libpng/Manifest b/media-libs/libpng/Manifest
index 4de304a9a1e5..956b4ca6759b 100644
--- a/media-libs/libpng/Manifest
+++ b/media-libs/libpng/Manifest
@@ -1,2 +1,4 @@
-DIST libpng-1.6.40-apng.patch.gz 10330 BLAKE2B e2a5ff10ebaf75019d20edb148ea26fd6b255842aa34e8af31a919ae3c059b28eb827831289f47428e5f55c239f23a600677fde58e74bf0a2db27b5001f9ccb1 SHA512 803c45c2bbaf6c12863a09fb4d307c629680835b11a01c456512c81ef705e4f96c29e98c2486970ff1d86335cb4bd7568a30482c3e69601275d2a31d294058db
+DIST libpng-1.6.40-apng-apng.patch.gz 10330 BLAKE2B e2a5ff10ebaf75019d20edb148ea26fd6b255842aa34e8af31a919ae3c059b28eb827831289f47428e5f55c239f23a600677fde58e74bf0a2db27b5001f9ccb1 SHA512 803c45c2bbaf6c12863a09fb4d307c629680835b11a01c456512c81ef705e4f96c29e98c2486970ff1d86335cb4bd7568a30482c3e69601275d2a31d294058db
+DIST libpng-1.6.40-libpng-apng-apng.patch.gz 10815 BLAKE2B 47b09d730d6be1d481ab48e511068a38fc3448339aaeab1d8ad21f26de6cb79006c64785de2e0514ff820a75101c0010b84cce923d10e8f6198e4e99916d08f2 SHA512 373cc9f0df15f7c77c0a59ddaac22374cfae37174b63a642e68e3a17a6d0bb1015399d771998c7eb6b356b634f157f0009743f4cc659f3b8e480a9533010ef9c
 DIST libpng-1.6.40.tar.xz 1021332 BLAKE2B 4dd2df57791ca68cc31ba966b9176ecb37458572c60eef34e31ff0d3266d25ad6ea9d2e8cae6bfaf7932b5c7bc231047d3ed139b3464304c41cc4d89611f5ba8 SHA512 a2ec37c529bf80f3fee3798191d080d06e14d6a1ffecd3c1a02845cb9693b5e308a1d82598a376101f9312d989d19f1fb6735b225d4b0b9f1b73f9f8a3edb17f
+DIST libpng-1.6.41.tar.xz 1035328 BLAKE2B 43d8d1c563d9df46b663f706dca9563e31e6e47a2809a77a5d059de8cfa348721054df724d08ac24ef4717ffc101989941127df2d026c9537532375d9b432b68 SHA512 046d0328255572ee2ccab7e751ed457b07e0aedc72474c2f4675a8303e628de3ef8afa1a00c60d768eb788546d1cda1e8b800b2497d9c352694faba6dde2c5b4
diff --git a/media-libs/libpng/libpng-1.6.40-r1.ebuild b/media-libs/libpng/libpng-1.6.40-r1.ebuild
index 427a7cace2c3..604859806599 100644
--- a/media-libs/libpng/libpng-1.6.40-r1.ebuild
+++ b/media-libs/libpng/libpng-1.6.40-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -12,8 +12,8 @@ HOMEPAGE="http://www.libpng.org/"
 SRC_URI="
 	mirror://sourceforge/${PN}/${P}.tar.xz
 	apng? (
-		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PV}/${PN}-${APNG_VERSION}-apng.patch.gz
-		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PN}-${APNG_VERSION}-apng.patch.gz
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PV}/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
 	)
 "
 
@@ -33,10 +33,10 @@ src_prepare() {
 	if use apng; then
 		case ${APNG_REPO} in
 			apng)
-				eapply -p0 "${WORKDIR}"/${PN}-${APNG_VERSION}-apng.patch
+				eapply -p0 "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
 				;;
 			libpng-apng)
-				eapply "${WORKDIR}"/${PN}-${APNG_VERSION}-apng.patch
+				eapply "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
 				;;
 			*)
 				die "Unknown APNG_REPO!"
diff --git a/media-libs/libpng/libpng-1.6.41.ebuild b/media-libs/libpng/libpng-1.6.41.ebuild
new file mode 100644
index 000000000000..b198fcd653b4
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.41.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool multilib-minimal
+
+APNG_REPO=libpng-apng # sometimes libpng-apng is more up to date
+APNG_VERSION="1.6.40"
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? (
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PV}/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
+		mirror://sourceforge/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
+	)
+"
+
+LICENSE="libpng2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	default
+
+	if use apng; then
+		case ${APNG_REPO} in
+			apng)
+				eapply -p0 "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
+				;;
+			libpng-apng)
+				eapply "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
+				;;
+			*)
+				die "Unknown APNG_REPO!"
+				;;
+		esac
+
+		# Don't execute symbols check with apng patch, bug #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(multilib_native_enable tools)
+		$(use_enable test tests)
+		$(use_enable cpu_flags_arm_neon arm-neon)
+		$(use_enable cpu_flags_x86_sse intel-sse)
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+
+	find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
+}