media-libs/openimageio: add 2.5.5.0

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34216
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

3 files changed, 208 insertions, 0 deletions

diff --git a/media-libs/openimageio/Manifest b/media-libs/openimageio/Manifest
index ab662df5f0ce..8cd680342d81 100644
--- a/media-libs/openimageio/Manifest
+++ b/media-libs/openimageio/Manifest
@@ -5,6 +5,7 @@ DIST openimageio-2.4.15.0.tar.gz 47894262 BLAKE2B 82afc48b3d9affb987d94c57d91fe9
 DIST openimageio-2.4.16.0.tar.gz 47894563 BLAKE2B 02788bb7ccc9bbcb84a44df0c86252545f89cf8dcd1b84443f185f43e60c9eb701e9c5e781c946dec797ec888c5ebdd5efb3f1d95b684c71cbb7271bf6f0da9e SHA512 f9835d6b5e938bdba462a64eb9cc3b89f27ea36b6b59f7143a9c0b2794f095ca68fbd26bdd7322b2b260e9ded5cc6a91f86ad11f292ad8163a1dfe55b9a3446c
 DIST openimageio-2.4.6.0.tar.gz 31951691 BLAKE2B c21caf6784f366200127ba17a296e2134fa0d494e2cbf9cf592d020fdb820f62db0269545ac37c3969d64ddd8352d06a4f002fa9a7b3f05503ca9ec7d4a15415 SHA512 6e4e5294209c533eb9cf7c8df89b531bc77547df28af0d7964e255ce78142c201d5aa92a1f5f3b17348fdfc7d2a7aa9f2121acdf22fa98a6a872f0d31936bdf5
 DIST openimageio-2.5.4.0.tar.gz 48107518 BLAKE2B 38ba0f01976cfbe0f81c04fe8e64ff9c5ab530204d45a7b566882a7ec31c378c61a9b6bc62d6453c51e7ed33cd514a758b5d8224a646e568c9abd6274ebc6b0c SHA512 db9576bbc0b77da19db957710e86d8979e9987e91ff6246b513197fa98545904a7d34873cc2ba3ee60deed0a00a757dafb8dfa604f1e52097a1848aef43427cd
+DIST openimageio-2.5.5.0.tar.gz 52025462 BLAKE2B d8d88d5e89815525fe7e75983b8d373058901614dcea9743a3851e242aa5f076b81ef3cc18764063e456ed9b79758d146c5d862be3a45d3671c59c7195acfa51 SHA512 d8ac989a6c7007089e3a29723889c9b9644d23ca9da1606da9f8c6bd7c0b301cf6a03f57c8eaaaca2a2fb2f3e79291f9dfa46ed31240a15d4650b83bf93ce96d
 DIST openimageio-oexr-test-image-df16e765fee28a947244657cae3251959ae63c00.tar.gz 252131865 BLAKE2B f5f2477897f84148574cdd02b673c7bdff49d8f45026375095bb6f184230466e2e60020be7583e5a5aa0aa9c971e7251979d3eeb2ee620d47342b1e4435427e0 SHA512 e89c2935496c5fec2ebe1175e9b9bd3aecb23374ec3947057195ee6d31a883c1a67c4dc754bf0a5b68859093b5e169b70ffabd4736cf67f9e3dc09f3299fc54f
 DIST openimageio-oexr-test-image-f17e353fbfcde3406fe02675f4d92aeae422a560.tar.gz 252226183 BLAKE2B b94fb08515e18821e5b88c10031ca53675c56f96397e00b4e186d8dfb9f8557bc935ff102d61835590dca6deeef90dba03b81fd76a7958ab4d0592c042c2130a SHA512 26b9b2cda9d48554b8a53f06bc20301f8ff77dc5e1d7caf9ec45aaaefd8578d3d4d4b2e0a1d1b0f697805fdc0c5d4bae4948cea21821df3006ac0f8b9020f85f
 DIST openimageio-oiio-test-image-245e50edede2792205080eadc1dedce33ff5c1e4.tar.gz 137900826 BLAKE2B e89fd990b5e3ef23a853fc554066804c2a092b74a7ee54e3f1654bf419904ca094fef2703cd2f29d90c6d2bc5b8c8808cf9e66eb858c6d8495fdb7941f5029d7 SHA512 6568d4171c7dbd12d86099fd3dc35bfe2cbd46af84e58884900c5cea6ccea0139eabdb6d2194217ab3cffac56a81d37db4fbae57eb2a05f7916c27fe75a51ee6
diff --git a/media-libs/openimageio/metadata.xml b/media-libs/openimageio/metadata.xml
index 84fca6c20010..3d6c024315eb 100644
--- a/media-libs/openimageio/metadata.xml
+++ b/media-libs/openimageio/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<use>
 		<flag name="dicom">Enable DICOM medical image file support via <pkg>sci-libs/dcmtk</pkg></flag>
+		<flag name="gui">Build iv (with Qt5)</flag>
 		<flag name="opencv">Enable OpenCV support via <pkg>media-libs/opencv</pkg></flag>
 		<flag name="openvdb">Enable OpenVDB support via <pkg>media-gfx/openvdb</pkg></flag>
 		<flag name="ptex">Enable Ptex texture mapping system file support via <pkg>media-libs/ptex</pkg></flag>
diff --git a/media-libs/openimageio/openimageio-2.5.5.0.ebuild b/media-libs/openimageio/openimageio-2.5.5.0.ebuild
new file mode 100644
index 000000000000..c9e9704df3d4
--- /dev/null
+++ b/media-libs/openimageio/openimageio-2.5.5.0.ebuild
@@ -0,0 +1,206 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+TEST_OIIO_IMAGE_COMMIT="aae37a54e31c0e719edcec852994d052ecf6541e"
+TEST_OEXR_IMAGE_COMMIT="df16e765fee28a947244657cae3251959ae63c00"
+inherit cmake flag-o-matic font python-single-r1
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="https://sites.google.com/site/openimageio/ https://github.com/OpenImageIO"
+SRC_URI="
+	https://github.com/AcademySoftwareFoundation/OpenImageIO/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? (
+		https://github.com/AcademySoftwareFoundation/OpenImageIO-images/archive/${TEST_OIIO_IMAGE_COMMIT}.tar.gz -> ${PN}-oiio-test-image-${TEST_OIIO_IMAGE_COMMIT}.tar.gz
+		https://github.com/AcademySoftwareFoundation/openexr-images/archive/${TEST_OEXR_IMAGE_COMMIT}.tar.gz -> ${PN}-oexr-test-image-${TEST_OEXR_IMAGE_COMMIT}.tar.gz
+	)
+"
+S="${WORKDIR}/OpenImageIO-${PV}"
+
+LICENSE="BSD"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv"
+
+X86_CPU_FEATURES=(
+	aes:aes sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( "${X86_CPU_FEATURES[@]/#/cpu_flags_x86_}" )
+
+IUSE="dicom doc ffmpeg gif gui jpeg2k opencv openvdb ptex python qt6 raw test +tools +truetype ${CPU_FEATURES[*]%:*}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} ) gui? ( tools )"
+
+# Not quite working yet
+RESTRICT="!test? ( test )" # test"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-bibtexextra
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-fontutils
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexextra
+	)
+"
+RDEPEND="
+	dev-libs/boost:=
+	dev-cpp/robin-map
+	dev-libs/libfmt:=
+	dev-libs/pugixml:=
+	>=media-libs/libheif-1.13.0:=
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	>=dev-libs/imath-3.1.2-r4:=
+	>=media-libs/opencolorio-2.1.1-r4:=
+	>=media-libs/openexr-3:0=
+	media-libs/tiff:=
+	sys-libs/zlib:=
+	dicom? ( sci-libs/dcmtk )
+	ffmpeg? ( media-video/ffmpeg:= )
+	gif? ( media-libs/giflib:0= )
+	jpeg2k? ( >=media-libs/openjpeg-2.0:2= )
+	opencv? ( media-libs/opencv:= )
+	openvdb? (
+		dev-cpp/tbb:=
+		media-gfx/openvdb:=
+	)
+	ptex? ( media-libs/ptex:= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	gui? (
+		media-libs/libglvnd
+		!qt6? (
+			dev-qt/qtcore:5
+			dev-qt/qtgui:5
+			dev-qt/qtopengl:5
+			dev-qt/qtwidgets:5
+		)
+		qt6? (
+			dev-qt/qtbase:6[gui,widgets,opengl]
+		)
+	)
+	raw? ( media-libs/libraw:= )
+	truetype? ( media-libs/freetype:2= )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+DOCS=(
+	CHANGES.md
+	CREDITS.md
+	README.md
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	use dicom || rm -r "${S}/src/dicom.imageio/" || die
+	cmake_src_prepare
+	cmake_comment_add_subdirectory src/fonts
+
+	if use test ; then
+		mkdir -p "${BUILD_DIR}"/testsuite || die
+		mv "${WORKDIR}/OpenImageIO-images-${TEST_OIIO_IMAGE_COMMIT}" "${BUILD_DIR}"/testsuite/oiio-images || die
+		mv "${WORKDIR}/openexr-images-${TEST_OEXR_IMAGE_COMMIT}" "${BUILD_DIR}"/testsuite/openexr-images || die
+	fi
+}
+
+src_configure() {
+	# Build with SIMD support
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd[*]} ]] && mysimd=("0")
+
+	# This is currently needed on arm64 to get the NEON SIMD wrapper to compile the code successfully
+	# Even if there are no SIMD features selected, it seems like the code will turn on NEON support if it is available.
+	use arm64 && append-flags -flax-vector-conversions
+
+	local mycmakeargs=(
+		-DCMAKE_CXX_STANDARD="17"
+		-DDOWNSTREAM_CXX_STANDARD="17"
+		"-DVERBOSE=ON"
+		"-DOIIO_BUILD_TOOLS=$(usex tools)"
+		"-DBUILD_TESTING=$(usex test)"
+		"-DOIIO_BUILD_TESTS=$(usex test)"
+		"-DOIIO_DOWNLOAD_MISSING_TESTDATA=OFF"
+		"-DINSTALL_FONTS=OFF"
+		"-DBUILD_DOCS=$(usex doc)"
+		"-DINSTALL_DOCS=$(usex doc)"
+		"-DSTOP_ON_WARNING=OFF"
+		"-DUSE_CCACHE=OFF"
+		"-DUSE_DCMTK=$(usex dicom)"
+		"-DUSE_EXTERNAL_PUGIXML=ON"
+		"-DUSE_NUKE=OFF" # not in Gentoo
+		"-DUSE_FFMPEG=$(usex ffmpeg)"
+		"-DUSE_GIF=$(usex gif)"
+		"-DUSE_OPENJPEG=$(usex jpeg2k)"
+		"-DUSE_OPENCV=$(usex opencv)"
+		"-DUSE_OPENVDB=$(usex openvdb)"
+		"-DUSE_PTEX=$(usex ptex)"
+		"-DUSE_PYTHON=$(usex python)"
+		"-DUSE_LIBRAW=$(usex raw)"
+		"-DUSE_FREETYPE=$(usex truetype)"
+		"-DUSE_SIMD=$(local IFS=','; echo "${mysimd[*]}")"
+	)
+
+	if use gui; then
+		mycmakeargs+=( -DENABLE_IV=ON -DUSE_OPENGL=ON -DUSE_QT=ON )
+		if ! use qt6; then
+			mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Qt6=ON )
+		fi
+	else
+		mycmakeargs+=( -DENABLE_IV=OFF -DUSE_QT=OFF )
+	fi
+
+	if use python; then
+		mycmakeargs+=(
+			"-DPYTHON_VERSION=${EPYTHON#python}"
+			"-DPYTHON_SITE_DIR=$(python_get_sitedir)"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	# TODO: investigate failures
+	local myctestargs=(
+		-E "(oiiotool|maketx|oiiotool-maketx|texture-crop|texture-crop.batch|texture-half|texture-half.batch|texture-uint16|texture-uint16.batch|texture-interp-bilinear|texture-interp-bilinear.batch|texture-interp-closest|texture-interp-closest.batch|texture-levels-stochaniso|texture-levels-stochaniso.batch|texture-levels-stochmip|texture-levels-stochmip.batch|texture-mip-onelevel|texture-mip-onelevel.batch|texture-mip-stochastictrilinear|texture-mip-stochastictrilinear.batch|texture-mip-stochasticaniso|texture-mip-stochasticaniso.batch|texture-uint8|texture-uint8.batch|texture-skinny|texture-skinny.batch|texture-icwrite|texture-icwrite.batch|jpeg2000-broken|openexr-damaged|openvdb-broken|texture-texture3d-broken|texture-texture3d-broken.batch|psd|ptex-broken|raw-broken|targa|tiff-depths|zfile|unit_simd|cineon|dds|openvdb.batch-broken|texture-texture3d.batch-broken|cmake-consumer|texture-udim|texture-udim2|texture-udim.batch|texture-udim2.batch)"
+	)
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	# can't use font_src_install
+	# it does directory hierarchy recreation
+	FONT_S=(
+		"${S}/src/fonts/Droid_Sans"
+		"${S}/src/fonts/Droid_Sans_Mono"
+		"${S}/src/fonts/Droid_Serif"
+	)
+	insinto "${FONTDIR}"
+	for dir in "${FONT_S[@]}"; do
+		doins "${dir}"/*.ttf
+	done
+}