media-libs/x264: add 0.0.20231114

Closes: https://bugs.gentoo.org/917583
Closes: https://bugs.gentoo.org/918105
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 87 insertions, 10 deletions

diff --git a/media-libs/x264/Manifest b/media-libs/x264/Manifest
index 4b11d2ba0042..b95b528c7338 100644
--- a/media-libs/x264/Manifest
+++ b/media-libs/x264/Manifest
@@ -1 +1,2 @@
 DIST x264-0.0.20220222.tar.bz2 777236 BLAKE2B 45e57c48b4b889f5c7b4ce87d1442d26d907aac47fb7c586b34239317a8b74bb93eac3058eed766728fbca6370656d9a6f070e8992643984a89560e28edf206d SHA512 1cf864059f83731ac47008c1af1d9ac06d06283439cf883a020f8a76e0c7efc3b525791d11efe8784d0e39ded68dd03794f0502fa64cc07df2f2de064a55e1d9
+DIST x264-0.0.20231114.tar.bz2 833229 BLAKE2B e8e60767d16ea11e55f9dd56f1c74535a06b07a498b91d4372872925915563b67fb917c5856e2e40e1f58acbab3142509d036cae8d56820bef0e16ee7bc35196 SHA512 7705c2827c6b280afc7403bce206f82ee94c1ba76c582d3e6ae017b9c4f08c4475ac70373f8a0bcda73046221456efc3f338c57aaf03c11f4d8e63f69bb94db5
diff --git a/media-libs/x264/x264-0.0.20231114.ebuild b/media-libs/x264/x264-0.0.20231114.ebuild
new file mode 100644
index 000000000000..7317a87e9e6a
--- /dev/null
+++ b/media-libs/x264/x264-0.0.20231114.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal toolchain-funcs flag-o-matic
+
+DESCRIPTION="Free library for encoding X264/AVC streams"
+HOMEPAGE="https://www.videolan.org/developers/x264.html"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://code.videolan.org/videolan/x264.git"
+else
+	X264_COMMIT="c196240409e4d7c01b47448d93b1f9683aaa7cf7"
+	SRC_URI="https://code.videolan.org/videolan/x264/-/archive/${X264_COMMIT}/x264-${X264_COMMIT}.tar.bz2 -> ${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+	S="${WORKDIR}/${PN}-${X264_COMMIT}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/164" # SONAME
+IUSE="cpu_flags_ppc_altivec +interlaced opencl pic static-libs cpu_flags_x86_sse +threads"
+
+ASM_DEP=">=dev-lang/nasm-2.13"
+DEPEND="
+	abi_x86_32? ( ${ASM_DEP} )
+	abi_x86_64? ( ${ASM_DEP} )
+	opencl? ( dev-lang/perl )
+"
+RDEPEND="opencl? ( >=virtual/opencl-0-r3[${MULTILIB_USEDEP}] )"
+
+DOCS=( AUTHORS doc/{ratecontrol,regression_test,standards,threads,vui}.txt )
+
+multilib_src_configure() {
+	tc-export CC
+
+	if [[ ${ABI} == x86 || ${ABI} == amd64 ]]; then
+		export AS="nasm"
+	else
+		export AS="${CC}"
+	fi
+
+	local asm_conf=""
+
+	if \
+		[[ ${ABI} == x86* ]] && { use pic || use !cpu_flags_x86_sse ; } \
+		|| [[ ${ABI} == "x32" ]] \
+		|| [[ ${CHOST} == armv5* ]] \
+		|| [[ ${ABI} == ppc* ]] && { use !cpu_flags_ppc_altivec ; } \
+		|| use mips && { ! test-compile 'c' 'int main(void){__asm__("addvi.b $w0, $w1, 1");return 0;}' ; }
+	then
+		asm_conf=" --disable-asm"
+	fi
+
+	"${S}/configure" \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--disable-cli \
+		--disable-avs \
+		--disable-lavf \
+		--disable-swscale \
+		--disable-ffms \
+		--disable-gpac \
+		--enable-pic \
+		--enable-shared \
+		--host="${CHOST}" \
+		--cross-prefix="${CHOST}-" \
+		$(usex interlaced "" "--disable-interlaced") \
+		$(usex opencl "" "--disable-opencl") \
+		$(usex static-libs "--enable-static" "") \
+		$(usex threads "" "--disable-thread") \
+		${asm_conf} || die
+}
diff --git a/media-libs/x264/x264-9999.ebuild b/media-libs/x264/x264-9999.ebuild
index cef3a4d4053a..7317a87e9e6a 100644
--- a/media-libs/x264/x264-9999.ebuild
+++ b/media-libs/x264/x264-9999.ebuild
@@ -1,31 +1,33 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit multilib-minimal toolchain-funcs flag-o-matic
 
-DESCRIPTION="A free library for encoding X264/AVC streams"
+DESCRIPTION="Free library for encoding X264/AVC streams"
 HOMEPAGE="https://www.videolan.org/developers/x264.html"
+
 if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://code.videolan.org/videolan/x264.git"
 else
-	# Download https://code.videolan.org/videolan/x264/-/archive/master/x264-master.tar.bz2
-	SRC_URI="https://dev.gentoo.org/~aballier/distfiles/${P}.tar.bz2"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-	S="${WORKDIR}/${PN}-master"
+	X264_COMMIT="c196240409e4d7c01b47448d93b1f9683aaa7cf7"
+	SRC_URI="https://code.videolan.org/videolan/x264/-/archive/${X264_COMMIT}/x264-${X264_COMMIT}.tar.bz2 -> ${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+	S="${WORKDIR}/${PN}-${X264_COMMIT}"
 fi
 
-SLOT="0/164" # SONAME
-
 LICENSE="GPL-2"
+SLOT="0/164" # SONAME
 IUSE="cpu_flags_ppc_altivec +interlaced opencl pic static-libs cpu_flags_x86_sse +threads"
 
 ASM_DEP=">=dev-lang/nasm-2.13"
-DEPEND="abi_x86_32? ( ${ASM_DEP} )
+DEPEND="
+	abi_x86_32? ( ${ASM_DEP} )
 	abi_x86_64? ( ${ASM_DEP} )
-	opencl? ( dev-lang/perl )"
+	opencl? ( dev-lang/perl )
+"
 RDEPEND="opencl? ( >=virtual/opencl-0-r3[${MULTILIB_USEDEP}] )"
 
 DOCS=( AUTHORS doc/{ratecontrol,regression_test,standards,threads,vui}.txt )