media-sound/bluez-alsa: Bump to version 4.0.0

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index c294ef4f4547..cb8ee1819256 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1,2 +1,3 @@
 DIST bluez-alsa-3.0.0.tar.gz 157776 BLAKE2B 68cc67dcfd303e624333d7dafa53a3ce0f91f55e58a9a1a51f17153eadfdca5acc1b12b2e41a11c4780909fe8283e0a9c859a7d755e38dd9aeebbf4ae9e0daf2 SHA512 094c91636c3f1803b3eb88e295683acc604be9f86d00022c196784b4ec88aa4a6cc20bdff0fdab2a7e5af3efe95ed8bd8c5486a8cd7896ec572bfa9e8e0f13d0
 DIST bluez-alsa-3.1.0.tar.gz 179984 BLAKE2B b0bd5008d1bcc972577d8626970834934cc9424b4dff5c9ede1b1bfb0ac6c62c50dd8a7b94bdaa8884354379fb4fe06d758f620b2f42207d85f68da5064b3499 SHA512 8b2644cb2114569cc896869f22352386a9362eeacae823423a63d9b21198f561d4af796700fcd3267556bb69ff2575569474a1da8e3a645b5a2e779882c27cbf
+DIST bluez-alsa-4.0.0.tar.gz 230879 BLAKE2B 998127cb4e03afc019679b80fc1ac7d56351aeb8274efe76a74d6c5600c4b8527d5463e864cc8f68c1fa82c1729ef38d8168e90e7092dfe5eaf5a7cf25ba4bfa SHA512 8a79e5a1189db2d39b2d772cb8f8cd51ebb96b9bd91489556195e83dfd16f40a581dce68c5ad9e886b66cec8a03ae7f959e8288bb4c5c87ea5a2bbd6aee9c5f0
diff --git a/media-sound/bluez-alsa/bluez-alsa-4.0.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-4.0.0.ebuild
new file mode 100644
index 000000000000..1343401528ab
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-4.0.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools bash-completion-r1 multilib-minimal systemd
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac aptx debug hcitop lame ldac man mpg123 ofono static-libs systemd test unwind upower"
+RESTRICT="!test? ( test )"
+
+# bluez-alsa does not directly link to upower but
+# is using the upower interface via dbus calls.
+RDEPEND="
+	>=dev-libs/glib-2.32[${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
+	aptx? ( media-libs/libopenaptx )
+	lame? ( media-sound/lame[${MULTILIB_USEDEP}] )
+	mpg123? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)
+	ldac? ( >=media-libs/libldac-2.0.0 )
+	ofono? ( net-misc/ofono )
+	systemd? ( sys-apps/systemd )
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	upower? ( sys-power/upower )
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/check
+		media-libs/libsndfile
+	)"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( app-text/pandoc )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-cli
+		--enable-faststream
+		--enable-rfcomm
+		--with-bash-completion="$(get_bashcompdir)"
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable lame mp3lame)
+		$(use_enable man manpages)
+		$(use_enable mpg123)
+		$(use_enable static-libs static)
+		$(use_enable systemd)
+		$(use_enable test)
+		$(use_with systemd systemdsystemunitdir $(systemd_get_systemunitdir))
+		$(multilib_native_use_enable aptx)
+		$(multilib_native_use_enable hcitop)
+		$(multilib_native_use_enable ldac)
+		$(multilib_native_use_enable ofono)
+		$(multilib_native_use_enable upower)
+		$(multilib_native_use_with aptx libopenaptx)
+		$(use_with unwind libunwind)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
+	#systemd_dounit "${FILESDIR}"/bluealsa.service
+
+	# Add config file to alsa datadir as well to preserve changes in /etc
+	insinto "/usr/share/alsa/alsa.conf.d/"
+	doins "src/asound/20-bluealsa.conf"
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}