media-sound/cava: drop 0.8.3, 0.9.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

3 files changed, 0 insertions, 146 deletions

diff --git a/media-sound/cava/Manifest b/media-sound/cava/Manifest
index e6f9f52f7a87..74101eb03ce0 100644
--- a/media-sound/cava/Manifest
+++ b/media-sound/cava/Manifest
@@ -1,3 +1 @@
-DIST cava-0.8.3.tar.gz 104797 BLAKE2B 0617273669fbd8d1c122e6b19975d54d42b5779339de89613b4fe5d6087bcf0ff93afe6234af238e489d6b72c3eca481140105000951ef007cc864b77ef49b65 SHA512 cd176428ff293572325d21769fd4fdb666b6301e0fe5c7a2c53af2399a26b3fd10e83647f9c9cc318f4c69cc28835323fb949cd76340c14670df8b544bffa0f0
-DIST cava-0.9.0.tar.gz 119267 BLAKE2B 6e409695fcc893892a1206b3d131fb091fcfac26db7f948d8d7b047e6e2a22bf05c613ff13b00b9a32c4eba6990a54755e1b2e816fe2db0e9f6140f688c2dd3a SHA512 ed5cd222565324553b598c01740c1178dcaf41f8fe715e301906f122e605e55ec080e3254e23459cab01d03ce5204bee1cc8821c871a5cb95181704522cec76d
 DIST cava-0.9.1.tar.gz 119287 BLAKE2B e6342ff8867747a2c15197c965b713e8ea1c5bd579725538e0e1745797280460ea6a7d6c5cca2776934eef24378d9661bcef5cfd5280a93de16b41201558c49d SHA512 21af220b53a2f45c8c43dfd2ba47c1c96a8fcccdbd11ca1ac59eea7a4f32c0e27c7d2056281d0293fd17d4d635b1c568c953567d6f0301c800b4a387332d2a7a
diff --git a/media-sound/cava/cava-0.8.3.ebuild b/media-sound/cava/cava-0.8.3.ebuild
deleted file mode 100644
index ed077f42a0f1..000000000000
--- a/media-sound/cava/cava-0.8.3.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="Console-based Audio Visualizer for Alsa"
-HOMEPAGE="https://github.com/karlstav/cava/"
-SRC_URI="https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="alsa +ncurses portaudio pulseaudio sdl sndio"
-
-RDEPEND="
-	dev-libs/iniparser:4
-	sci-libs/fftw:3.0=
-	alsa? ( media-libs/alsa-lib )
-	ncurses? ( sys-libs/ncurses:= )
-	portaudio? ( media-libs/portaudio )
-	pulseaudio? ( media-libs/libpulse )
-	sdl? ( media-libs/libsdl2[opengl,video] )
-	sndio? ( media-sound/sndio:= )"
-DEPEND="${RDEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
-)
-
-src_prepare() {
-	default
-
-	echo ${PV} > version || die
-	eautoreconf
-}
-
-src_configure() {
-	local econfargs=(
-		$(use_enable alsa input-alsa)
-		$(use_enable portaudio input-portaudio)
-		$(use_enable pulseaudio input-pulse)
-		$(use_enable sndio input-sndio)
-
-		$(use_enable ncurses output-ncurses)
-		$(use_enable sdl output-sdl)
-
-		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
-	)
-
-	econf "${econfargs[@]}"
-}
-
-pkg_postinst() {
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "A default ~/.config/cava/config will be created after initial"
-		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
-		elog "for configuring audio input and more."
-	fi
-}
diff --git a/media-sound/cava/cava-0.9.0.ebuild b/media-sound/cava/cava-0.9.0.ebuild
deleted file mode 100644
index 88134f272ff1..000000000000
--- a/media-sound/cava/cava-0.9.0.ebuild
+++ /dev/null
@@ -1,83 +0,0 @@
-# Copyright 2022-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools toolchain-funcs
-
-DESCRIPTION="Console-based Audio Visualizer for Alsa"
-HOMEPAGE="https://github.com/karlstav/cava/"
-SRC_URI="
-	https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz
-		-> ${P}.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="alsa +ncurses pipewire portaudio pulseaudio sdl sndio"
-
-RDEPEND="
-	dev-libs/iniparser:4
-	sci-libs/fftw:3.0=
-	alsa? ( media-libs/alsa-lib )
-	ncurses? ( sys-libs/ncurses:= )
-	pipewire? ( media-video/pipewire:= )
-	portaudio? ( media-libs/portaudio )
-	pulseaudio? ( media-libs/libpulse )
-	sdl? (
-		media-libs/libglvnd
-		media-libs/libsdl2[opengl,video]
-	)
-	sndio? ( media-sound/sndio:= )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	sdl? ( sys-devel/autoconf-archive )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
-)
-
-src_prepare() {
-	default
-
-	echo ${PV} > version || die
-	eautoreconf
-}
-
-src_configure() {
-	local econfargs=(
-		$(use_enable alsa input-alsa)
-		$(use_enable pipewire input-pipewire)
-		$(use_enable portaudio input-portaudio)
-		$(use_enable pulseaudio input-pulse)
-		$(use_enable sndio input-sndio)
-
-		$(use_enable ncurses output-ncurses)
-		$(use_enable sdl output-sdl)
-		# note: not behind USE=opengl and sdl2[opengl?] given have not gotten
-		# normal output-sdl to work without USE=opengl on sdl either way
-		$(use_enable sdl output-sdl_glsl)
-
-		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
-	)
-
-	# autoconf-archive (currently) does not support -lOpenGL for libglvnd[-X]
-	use sdl && econfargs+=( GL_LIBS="$($(tc-getPKG_CONFIG) --libs opengl || die)" )
-
-	econf "${econfargs[@]}"
-}
-
-pkg_postinst() {
-	if [[ ! ${REPLACING_VERSIONS##* } ]]; then
-		elog "A default ~/.config/cava/config will be created after initial"
-		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
-		elog "for configuring audio input and more."
-	elif ver_test ${REPLACING_VERSIONS##* } -lt 0.9; then
-		elog "If used, the noise_reduction config option in ~/.config/cava/config needs"
-		elog "to be updated from taking a float to integer (e.g. replace 0.77 with 77)."
-	fi
-}